%{
#include "replacement.h"
#include "macros.h"
%}

%struct-type
%omit-struct-type
%compare-lengths
%readonly-tables
%null-strings
%includes
%define lookup-function-name gumbo_get_foreign_attr_replacement
%define slot-name from
ForeignAttrReplacement;

%%
"xlink:actuate", "actuate", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:arcrole", "arcrole", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:href", "href", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:role", "role", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:show", "show", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:title", "title", GUMBO_ATTR_NAMESPACE_XLINK
"xlink:type", "type", GUMBO_ATTR_NAMESPACE_XLINK
"xml:lang", "lang", GUMBO_ATTR_NAMESPACE_XML
"xml:space", "space", GUMBO_ATTR_NAMESPACE_XML
"xmlns", "xmlns", GUMBO_ATTR_NAMESPACE_XMLNS
"xmlns:xlink", "xlink", GUMBO_ATTR_NAMESPACE_XMLNS
