Plot 0
	name <Bandit Job 2>

    % Leader Mission Template
    % v1.302 Standard

	% Element1 is just the bandit of some town.
	element1 <Character Bandit Villainous HasMecha>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  P1 = Time Limit
	%  P2 = Combat Indicator, if V2=1 combat has been entered
	%  P3 = Email sent indicator.

	% Time limit. This plot will conclude in one day, or immediately
	% if NPC E1 is killed.
	start <ifNPCOK E1 else GoDelete if= V1 0 else GoCheckTime V= 1 ComTime V+ 1 86400>
	GoCheckTime <if= V2 0 ifG ComTime V1 AdvancePlot 0>
	GoDelete <AdvancePlot 0>

	% Combat check. If combat has been entered, V2=1.
	% Combat ends in victory if the number of active masters on
	% team two drops to zero, or ends in defeat is the number of
	% active masters on team one drops to zero. After combat, V2=3
	% if the player was victorious or V2=2 is the player lost.
	nu1 <if= T1 0 if= V2 1  V= 2 2  LoseRenown>
	nu2 <if= T2 0 if= V2 1  V= 2 3  Reputation 6  1  XPV 50 Salvage>

	% Email check. The NPC might send the PC email about this mission.
	5Min <if= d80 23 if= V3 0 ifG RReact E1 d150 ifPCChaotic V= 3 1 Email 1>

	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 - 05 :  Email Messages.
	%  The NPC is offering the PC a mission via email.
	Msg1   <\PERSONA E1 @ \SCENE EScene 1 :// I have a job offer that you cannot refuse.>
	Msg1_2 <\PERSONA E1 @ \SCENE EScene 1 :// Your services and mecha are required. Give me a call.>
	Msg1_3 <\PERSONA E1 @ \SCENE EScene 1 :// If you're not in jail right now I have a favor to ask.>

sub
	% This next bit is the conversation which will happen when the
	% PC speaks to E1.
	Persona 1
	rumor <!1 has dark ambitions.>

	% ********************
	% *** SCRIPT BLOCK ***
	% ********************
	%  V1 = Job offer counter, V1=1 is job offered, V1=-1 if job denied
	%  V3 = Threat value of enemy mecha
	%  V4 = Reward offered to PC for the mission

	greeting <NewChat if= P2 3 else GoCheckLoss Say 1 AddReact d5 CashPrize V4 AdvancePlot 0>
	GoCheckLoss <if= P2 2 else GoCheckMission Say 6 AdvancePlot 0>
	GoCheckMission <if= V1 1 else GoCheckFirst Say 101 Goto GoAddComOps>

	% The first time the PC speaks to the NPC, initialize everything.
	GoCheckFirst <if= V1 0 else GoDenied V= 1 -1 V= 3 Threat PCRep 6 100 V= 4 Reward V3 150 Goto GoCheckOffer>
	GoCheckOffer <if= P3 1 else GoMakeOffer Say 11  Goto GoAddAcceptOps>
	% If the PC has "the right stuff", an offer will be made immediately.
	% If not, no offer will be made at all. In the example provided
	% below, "the right stuff" is a Lawful reputation + being liked.
	GoMakeOffer  <ifG React d25 else GoNoOffer ifG PCMeks 0 else GoNoMeks ifPCChaotic else GoNoOffer Say 16 Goto GoAddAcceptOps>

	GoAddAcceptOps <AddChat 1 AddChat 4>
	GoAddComOps <AddChat 7 AddChat 9 AddChat 11>
    GoNoMeks <Say 106 AdvancePlot 0>
	GoNoOffer <Say 102 AdvancePlot 0>
	% If the mission was denied but not previously cleaned up, do
	% that now.
	GoDenied <SayAnything AdvancePlot 0>

	% PC will accept the job. Descibe the mission.
	result1 <NewChat V= 1 1 Say 21 Memo 103 Goto GoAddComOps>

	% PC refuses the job.
	result4 <NewChat Say 104 AdvancePlot 0>

	% PC will enter combat now.
	result7 <EndChat Say 26 Goto GoStartCombat>
	GoStartCombat <SavePos P= 2 1 Reputation 2 -2 Dynamic 2 V3 .nu1 .nu2 Encounter 10 1 .enemydata>
	.nu1 <if= T1 0 Return>
	.nu2 <if= T2 0 Salvage Return>
	.enemydata <Villainous Chaotic Young>

	% PC will ask how many points the enemy has.
	result9 <NewChat Say 31 AddChat 7 AddChat 11>

	% PC needs some time to get ready.
	result11 <NewChat Say 105>

	% *********************
	% *** MESSAGE BLOCK ***
	% *********************

	% 01 :  Player has won the battle and is being paid.
	Msg1 <They won't be bothering me again. Here's your cash.>
	Msg1_1 <Remind me never to get on your bad side. Here's your pay for that mission.>
	Msg1_2 <Here you go. If I ever need your help again, I'll call.>
	Msg1_3 <That was quite a battle. Here's the money we agreed on.>
	Msg1_4 <Here's your money.>
	Msg1_5 <You're a vicious pilot. That was great. Here's your cash.>

	% 06 :  Player has lost the battle.
	Msg6 <I don't want to talk about it.>
	Msg6_7 <You have failed me, \PC . Fortunately I am nothing if not understanding.>
	Msg6_8 <>
	Msg6_9 <>
	Msg6_10 <>

	% 11 :  PC got email about mission; asked to accept
	Msg11 <There are a couple of rivals that have to be eliminated, and I need a good pilot to do that.>
	Msg11_2 <Ah, \PC , how convenient of you to show up right now. I have a big operation that's about to start.>
	Msg11_3 <>
	Msg11_4 <>
	Msg11_5 <>

	% 16 :  Player has "the right stuff"; will be offered mission.
	Msg16 <I've got a good plan going on. By tonight I'm gonna be moving up the ranks.>
	Msg16_7 <>
	Msg16_8 <>
	Msg16_9 <>
	Msg16_0 <>

	% 21 :  PC has accepted; describe the mission.
	Msg21 <A couple of kids got their hands on some light meks and now they think they're a gang. I need you to eliminate them. If you can pull this off it's worth $ \VAL V4 plus salvage.>
	Msg21_1 <Another gang has just recruited an ex-mercenary and all of his equipment. We need to eliminate them before they can move against us. Pay is $ \VAL V4 for the hit, plus you can keep any leftover meks.>
	Msg21_2 <We've been double crossed by another gang. I can give you $ \VAL V4 to take them all out. I want no survivors. Do what you like with the salvage.>
	Msg21_3 <Two of our rivals have just joined forces. They've got a very impressive mecha force now... It's worth $ \VAL V4 if you can remove them from the game, and you can keep the salvage.>
	Msg21_4 <Our guys have been falling behind in the technology curve, but if someone could eliminate the competition's new meks we'd be on top again. How about $ \VAL V4 for the job? Plus salvage rights, of course.>
	Msg21_5 <Some outsiders just moved into town. I don't know where they came from, but they've got some awesome machines. I need them eliminated. The job pays $ \VAL V4 plus salvage. How about it?>
	Msg21_6 <One of the big gangs in the area has been keeping the rest of us down. I need for them to be taken back a notch or two. Upon elimination of the gang I'll give you $ \VAL V4 , and the salvage is yours. What do you say?>
	Msg21_7 <A rival gang has just acquired some military grade hardware. I need those meks annihilated as soon as possible. This mission pays $ \VAL V4 and salvage.>
	Msg21_8 <One of the rival gangs has been pushing into our territory. I need someone to teach them a permanent lesson. You'll make $ \VAL V4 plus whatever salvage is left over. What do you think?>
	Msg21_9 <Some young thugs just bought their first armor units... I need you to make sure it's also their last. I'll give you $ \VAL V4 for the job, along with salvage rights.>

	% 26 :  Combat is starting
	Msg26 <This is all the information that you need to know. Come back here afterwards and I'll give you your cut.>
	Msg26_7 <>
	Msg26_8 <>
	Msg26_9 <>
	Msg26_10 <>

	% 31 :  Describe enemy point value
	Msg31 <They have \VAL V3 threat points of mecha. I trust this will not be a problem.>
	Msg31_2 <>
	Msg31_3 <>
	Msg31_4 <>
	Msg31_5 <>


	% 101 :  Player is back from repairs, time to start mission.
	Msg101 <Are you ready to start the heist yet?>
	% 102 :  Player doesn't have "the right stuff" for this mission.
	Msg102 <I've got no time for you right now.>
	Msg102_1 <Nothing is for free... If you want anything, you need the power to take it.>
	% 103 :  Memo
	Msg103 <\ELEMENT 1 in \SCENE EScene 1 offered you a criminal mission.>
	% 104 :  PC didn't want the job.
	Msg104 <You don't have what it takes. Get out of here.>
	% 105 :  PC needs time to get ready.
	Msg105 <Do whatever you need to do, then come back here and we'll start.>
    Msg106 <Mecha are power. Without one, you've got nothing.>

	% 01 :  PC will accept the mission.
	Prompt1 <You better have a share for me.>
	Prompt1_2 <>
	Prompt1_3 <>

	% 04 :  PC doesn't want this mission.
	Prompt4 <I couldn't care less about your plans.>
	Prompt4_5 <This isn't my kind of job.>
	Prompt4_6 <>

	% 07 :  Combat is starting.
	prompt7 <Leave those suckers to me.>
	prompt7_8 <I'm ready to go.>

	% 09 :  How many points?
	prompt9 <What am I facing out there?>
	prompt9_10 <Tell me more about their mecha.>

	% 11 :  Just a minute...
	prompt11 <Wait for me to get ready, alright?>
	prompt11_2 <Just a minute, I need to reload.>

end
