Innhold

# Regnearksfunksjoner

Denne delen inneholder beskrivelser av regneark-funksjonene sammen med et eksempel.

For å bruke denne funksjonen …

Sett inn → Funksjon → Kategori Regneark

## FEIL.TYPE

Returnerer et tall som representerer en spesifikk feiltype, eller feilverdien #N/A, hvis det ikke er noen feil.

## STYLE

Bruker en stil på cellen som inneholder formelen.

## ADDRESSE (ADDRESS på engelsk)

Gir en celleadresse (referanse) som tekst, i følge de oppgitte rad- og kolonnenumrene. Du kan finne ut om adressen er tolket som en absolutt adresse (for eksempel $A$1), relativ adresse (A1) eller i blandet form (A$1 eller $A1). Du kan også angi navnet til regnearket.

Av hensyn til interoperabilitet støtter funksjonene ADRESSE og INDIREKTE (INDIRECT på engelsk) en valgfri parameter for å angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT på engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, så blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, så blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT på engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

Når du åpner dokumenter fra ODF 1.0/1.1-format, vil ADRESSE-funksjonene som viser et arknavn som den fjerde parameteren skifte arknavnet til å bli den femte parameteren. En ny fjerde parameter med verdien 1 vil bli satt inn.

Når du lagrer et dokument i ODF 1.0/1.1-format, hvis ADRESSE-funksjoner har en fjerde parameter, vil denne parameteren bli fjernet.

Ikke lagre et regneark i det gamle ODF 1.0/1.1-formatet hvis ADRESSE-funksjonens nye fjerde parameter ble brukt med en verdi på 0.

Den INDIREKTE-funksjonen lagres uten konvertering til ODF 1.0/1.1-format. Hvis den andre parameteren var til stede, vil en eldre versjon av Calc returnere en feil for den funksjonen.

#### Syntaks

ADRESSE(Rad; Kolonne [; Abs [; A1 [; "Ark"]]])

Rad tilsvarer radnummeret for cellereferansen

Kolonne tilsvarer kolonnenummeret for cellereferansen (tallet, ikke bokstaven)

ABS bestemmer typen av referanse:

1: absolutt ($A$1)

2: radreferansetype er absolutt; kolonnereferanse er relativ (A$1)

3: rad (relativ); kolonne (absolutt) ($A1)

4: relativ (A1)

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

Ark tilsvarer navnet på arket. Det kan være plassert i dobbelt hermetegn.

### Eksempel:

=ADRESSE(1;1;2;;"Ark2") returnerer følgende: Ark2.A$1

Hvis formelen ovenfor er i celle B2 i gjeldende ark, og celle A1 i ark 2 inneholder verdien -6, kan du referere indirekte til den refererte cellen ved å bruke en funksjon i B2 ved å skrive inn =ABS(INDIRECT(B2)). Resultatet er den absolutte verdien av cellereferansen spesifisert i B2, som i dette tilfellet er 6.

## ANTALL.ARK (SHEETS på engelsk)

Finn antall ark i en referanse. Hvis du ikke angir noen parametere gir funksjonen antall ark i dette dokumentet.

#### Syntaks

ARK([Referanse])

Referanse er referansen til et ark eller et område. Denne parameteren er valgfri.

#### Eksempel

=ANTALL.ARK(Ark1.A1:Ark3.G12) gir 3, hvis Ark1, Ark2 og Ark3 finnes i den angitte rekkefølgen.

## DDE

Gir resultatet av en DDE-basert lenke. Hvis innholdet i det lenkede området endres, vil også resultatet endres. Du må laste regnearket på nytt eller velge Rediger – Lenker for å se de oppdaterte lenkene. Det er ikke tillatt med lenker fra en plattform til en annen, for eksempel fra en installasjon av LibreOffice på en Windows-maskin til et dokument opprettet på en Linux-maskin.

#### Syntaks

DDE("Server"; "Fil"; "Område" [; Modus])

Server er navnet på en serverapplikasjon. LibreOffice-applikasjoner har servernavnet "soffice".

Fil er det fullstendige filnavnet med sti oppgitt.

Område er området som inneholder dataen som skal valideres.

Modus er en valgfri parameter som bestemmer den metoden som DDE-tjeneren bruker for å gjøre om sine data til tall.

Modus | Effekt
--- | ---
0 eller manglende | Tallformat fra cellestilten «Standard»
1 | Data blir alltid fortolket som standard US engelsk-format.
2 | Data blir hentet som tekst; ingen omgjøring til tall.

#### Eksempel

=DDE("soffice";"c:\office\document\data1.ods";"ark1.A1") leser innholdet i celle A1 i ark1 i LibreOffice Calc regnearkdata1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Dagens motto") returnerer et motto i cellen som inneholder denne formelen. Først må du skrive inn en linje i motto.odt-dokumentet som inneholder mottoteksten og definere den som den første linjen i en seksjon kalt Dagens motto (i LibreOffice Writer under Sett inn - Seksjon). Hvis mottoet er endret (og lagret) i LibreOffice Writer-dokumentet, oppdateres mottoet i alle LibreOffice Calc-celler der denne DDE-koblingen er definert.

## FEILTYPE (ERRORTYPE på engelsk)

Returnerer tallet som tilsvarer en feilverdi som oppstår i en annen celle. Ved hjelp av dette nummeret, kan du generere en feilmeldingstekst.

Dersom det oppstår en feil, vil funksjonen gi en logisk eller numerisk verdi.

Statuslinjen viser den forhåndsdefinerte feilkoden fra LibreOffice hvis du klikker på cellen som inneholder feilen.

#### Syntaks

FEILTYPE(Referanse)

Referanse inneholder adressen på den cellen som feilen oppstår i.

#### Eksempel

Hvis celle A1 viser Err:518, gir funksjonen =FEILTYPE(A1) tallet 518.

#### Teknisk informasjon

Denne funksjonen er ikke en del av Open Document Format for Office-applikasjoner (OpenDocument) versjon 1.3. Del 4: Rekalkulert Formel (OpenFormula) Format-standard. Navnerommet er

ORG.OPENOFFICE.ERRORTYPE

## FINN.KOLONNE (HLOOKUP på engelsk)

Søker etter en verdi og en referanse til cellene nedenfor det merkede området. Funksjonen sjekker om den første raden i en tabell inneholder en viss verdi. Funksjonen gir så verdien i en rad i tabellen, angitt av Indeks, i den samme kolonnen.

Søket støtter jokertegn eller regulære uttrykk. Med regulære uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for å finne den første plasseringen av "alle" etterfulgt av tegn. Hvis du vil søke etter en tekst som også er et regulært uttrykk, må du enten bruke hvert regulært uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulære uttrykk av og på i LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn .

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntaks

HLOOKUP(Oppslag; Matrise; Indeks [; SortedRangeLookup])

For en forklaring på parameterne, se: VLOOKUP (kolonner og rader utveksles)

Håndtering av tomme celler

#### Eksempel

Anta at vi har bygget en liten databasetabell som okkuperer celleområdet A1:DO4 og inneholder grunnleggende informasjon om 118 kjemiske elementer. Den første kolonnen inneholder radoverskriftene "Element", "Symbol", "Atomnummer" og "Relativ atommasse". Påfølgende kolonner inneholder relevant informasjon for hvert av elementene, sortert fra venstre til høyre etter atomnummer. For eksempel inneholder cellene B1:B4 "Hydrogen", "H", "1" og "1.008", mens cellene DO1:DO4 inneholder "Oganesson", "Og", "118" og "294".

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Hydrogen | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomnummer | 1 | 2 | 3 | ... | 118
4 | Relativ atommasse | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returnerer "Pb", symbolet for bly.

=HLOOKUP("Gull"; $A$1:$DO$4; 3; 0) returnerer 79, atomnummeret for gull.

=HLOOKUP("Karbon"; $A$1:$DO$4; 4; 0) returnerer 12.011, den relative atommassen til karbon.

## FINN.NÅ (LOOKUP på engelsk)

Returnerer innholdet i en celle enten fra en rad eller én kolonne. Eventuelt returneres den tildelte verdien (av samme indeks) i en annen kolonne og rad. I motsetning til VLOOKUP og HLOOKUP , kan søke- og resultatvektor være i forskjellige posisjoner; de trenger ikke være tilstøtende. I tillegg må søkevektoren for LOOKUP sorteres stigende, ellers vil søket ikke gi noen brukbare resultater.

Hvis FINN.NÅ (LOOKUP på engelsk) ikke kan finne søkekriteriet, benyttes den største verdien i søkeretningen som er mindre enn eller lik søkekriteriet.

Søket støtter jokertegn eller regulære uttrykk. Med regulære uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for å finne den første plasseringen av "alle" etterfulgt av tegn. Hvis du vil søke etter en tekst som også er et regulært uttrykk, må du enten bruke hvert regulært uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulære uttrykk av og på i LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn .

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntaks

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup er verdien av en hvilken som helst type som skal ses etter; oppgis enten direkte eller som referanse.

SearchVector er et område med én rad eller én kolonne som skal søkes i.

ResultVector er et annet område med én rad eller én kolonne som resultatet av funksjonen er hentet fra. Resultatet er cellen til resultatvektoren med samme indeks som forekomsten funnet i søkevektoren.

Håndtering av tomme celler

#### Eksempel

=LOOKUP(A1;D1:D100;F1:F100) søker i den tilsvarende cellen i området D1:D100 etter tallet du skrev inn i A1. For forekomsten som ble funnet, bestemmes indeksen, for eksempel den 12. cellen i dette området. Deretter returneres innholdet i den 12. cellen som verdien av funksjonen (i resultatvektoren).

## FINN.RAD (VLOOKUP på engelsk)

Vertikalt søk med referanse til tilstøtende celler til høyre. Denne funksjonen sjekker om en bestemt verdi finnes i den første kolonnen i en matrise. Funksjonen returnerer deretter verdien i samme rad i kolonnen navngitt av Indeks. Hvis parameteren Sortert er utelatt eller satt til TRUE eller én, antas det at dataene er sortert i stigende rekkefølge. I dette tilfellet, hvis det eksakte oppslag ikke blir funnet, vil den siste verdien som er mindre enn kriteriet bli returnert. Hvis Sortert er satt til USANN eller null, må et eksakt samsvar finnes, ellers vil feilen Feil: Verdi ikke tilgjengelig bli resultatet. Med en verdi på null trenger ikke dataene å sorteres i stigende rekkefølge.

Søket støtter jokertegn eller regulære uttrykk. Med regulære uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for å finne den første plasseringen av "alle" etterfulgt av tegn. Hvis du vil søke etter en tekst som også er et regulært uttrykk, må du enten bruke hvert regulært uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulære uttrykk av og på i LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn .

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntaks

=VLOOKUP(Oppslag; Matrise; Indeks [; SortedRangeLookup])

Oppslag er verdien av en hvilken som helst type som ble sett etter i den første kolonnen i matrisen.

Matrise er referansen, som skal omfatte minst like mange kolonner som tallet som sendes i Index-argumentet.

Indeks er kolonnenummeret i området som inneholder verdien som skal returneres. Den første kolonnen har tallet 1.

SortedRangeLookup er en valgfri parameter som indikerer om den første kolonnen i matrisen inneholder områdegrenser i stedet for vanlige verdier. I denne modusen returnerer oppslaget verdien i raden med første kolonne med verdi lik eller mindre enn Oppslag. Den kan for eksempel inneholde datoer da en skatteverdi var endret, og verdiene representerer derfor startdatoer for en periode da en spesifikk skatteverdi var effektiv. Derfor vil søk etter en dato som er fraværende i den første matrisekolonnen, men som faller mellom noen eksisterende grensedatoer, gi den laveste av dem, slik at du kan finne ut at dataene er effektive til den søkte datoen. Skriv inn den boolske verdien USANN eller null hvis den første kolonnen ikke er en områdegrenseliste. Når denne parameteren er SANN eller ikke gitt, må den første kolonnen i matrisen sorteres i stigende rekkefølge. Sorterte kolonner kan søkes mye raskere og funksjonen returnerer alltid en verdi, selv om søkeverdien ikke ble matchet nøyaktig, hvis den er større enn den laveste verdien i den sorterte listen. I usorterte lister må søkeverdien samsvare nøyaktig. Ellers vil funksjonen returnere #N/A med meldingen: Feil: Verdi ikke tilgjengelig.

Håndtering av tomme celler

#### Eksempel

Du vil legge inn nummeret til en rett på menyen i celle A1, og navnet på retten skal vises som tekst i nabocellen (B1) umiddelbart. Nummer til navn-tildelingen finnes i D1:E100-arrayen. D1 inneholder 100, E1 inneholder navnet Grønnsaksuppe, og så videre, for 100 menyelementer. Tallene i kolonne D er sortert i stigende rekkefølge; Derfor er den valgfrie parameteren Sortert ikke nødvendig.

Skriv inn følgende formel i B1:

=FINN.RAD(A1; D1:E100; 2)

Så snart du skriver inn et tall i A1 vil B1 vise den tilsvarende teksten i den andre kolonnen med referanse D1:E100. Hvis du legger inn et ikke-eksisterende tall, vises teksten med neste tall nede. For å forhindre dette, skriv inn FALSE som siste parameter i formelen slik at det genereres en feilmelding når et ikke-eksisterende tall legges inn.

## FORSKYVNING (OFFSET på engelsk)

Gir verdien til en celle som ligger et visst antall rader og kolonner fra et gitt referansepunkt.

Denne funksjonen beregnes alltid på nytt hver gang en ny beregning skjer.

#### Syntaks

OFFSET(Referanse; Rader; Kolonner [; Høyde [; Bredde]])

Referanse er cellen hvorfra funksjonen leter etter den nye referansen.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

Høyde (valgfri) er den valgfrie loddrette høyden på et område som begynner ved den nye referanseposisjonen.

Bredde (valgfri) er den vannrette bredden for et område som begynner ved den nye referanseposisjonen.

Argumentene Høyde og Bredde kan ikke føre til null eller et negativt antall av rader eller kolonner.

Argumentene Høyde og Bredde kan ikke føre til null eller et negativt antall av rader eller kolonner.

I LibreOffice Calc-funksjoner kan parametre merket som «valgfri» kun utelates hvis ingen parameter følger etter. For eksempel i en funksjon med fire parametre, hvor de siste to parametrene er merket som «valgfri», kan du utelade parameter 4 eller parametrene 3 og 4, men du kan ikke utelate parameter 3 alene.

#### Eksempel

=FORSKYVNING(A1; 2; 2) gir verdien i celle C3 (A1 flyttet med to rader og to kolonner nedover). Hvis C3 inneholder verdien 100 gir denne funksjonen verdien 100.

=FORSKYVNING(B2:C3;1;1) gir en referanse til B2:C3 flyttet 1 rad ned og en kolonne til høyre (C3:D4).

=FORSKYVNING(B2:C3;-1;-1) gir en referanse til B2:C3 flyttet 1 rad opp og en kolonne til venstre (A1:B2).

=FORSKYVNING(B2:C3;0;0;3;4) gir en referanse til B2:C3 med størrelsen endret til 3 rader og 4 kolonner (B2:E4).

=FORSKYVNING(B2:C3;1;0;3;4) gir en referanse til B2:C3 flyttet en rad ned og med størrelsen endret til 3 rader og 4 kolonner (B2:E4).

=SUMMER(FORSKYVNING(A1;2;2;5;6)) bestemmer summen av området som starter i celle C3 og har en høyde på 5 rader og en bredde av 6 kolonner (område=C3:H7).

Hvis Bredde eller Høyde er gitt, returnerer OFFSET-funksjonen en celleområdereferanse. Hvis Referanse er en enkeltcellereferanse og både Bredde og Høyde er utelatt, returneres en enkeltcellereferanse.

## HENTPIVOTDATA

GETPIVOTDATA-funksjonen returnerer en resultatverdi fra en pivottabell. Verdien adresseres ved hjelp av felt- og elementnavn, så den forblir gyldig hvis oppsettet til pivottabellen endres.

#### Syntaks

To forskjellige syntaksdefinisjoner kan brukes:

GETPIVOTDATA(Målfelt; pivottabell[; Felt 1; Element 1][; ... [Felt 126; Element 126]])

eller

GETPIVOTDATA(pivottabell; Begrensninger)

Syntaks nr. 2 antas å være brukt hvis eksakt to parametre er gitt, hvor den første parameteren er en referanse til en celle eller et celleområde. Det første syntaks antas å være brukt i alle andre tilfeller. Funksjonsveiviseren viser det første syntaks.

### Første syntaks

TargetField er en streng som velger ett av pivottabellens datafelt. Strengen kan være navnet på kildekolonnen, eller datafeltnavnet som vist i tabellen (som "Sum - Salg").

pivottabell er en referanse til en celle eller et celleområde som er plassert i en pivottabell eller inneholder en pivottabell. Hvis celleområdet inneholder flere pivottabeller, brukes tabellen som ble opprettet sist.

Hvis ingen Felt n / Vare n-par er gitt, returneres totalsummen. Ellers legger hvert par til en begrensning som resultatet må tilfredsstille. Felt n er navnet på et felt fra pivottabellen. Element n er navnet på et element fra det feltet.

Hvis pivottabellen bare inneholder en enkelt resultatverdi som oppfyller alle begrensningene, eller et subtotalresultat som oppsummerer alle samsvarende verdier, returneres dette resultatet. Hvis det ikke er noe samsvarende resultat, eller flere uten en delsum for dem, returneres en feil. Disse betingelsene gjelder for resultater som er inkludert i pivottabellen.

Hvis kildedataene inneholder oppføringer som er skjult av innstillingene i pivottabellen, ignoreres de. Rekkefølgen av felt/element-parene er ikke signifikant. Felt- og elementnavn skiller ikke mellom store og små bokstaver.

Hvis det ikke er gitt noen begrensning for et filter, brukes feltets valgte verdi implisitt. Hvis en begrensning for et filter er gitt, må den samsvare med feltets valgte verdi, ellers returneres en feil. Filtre er feltene øverst til venstre i en pivottabell, fylt ut ved hjelp av "Filtre"-området i pivottabelllayoutdialogen. Fra hvert filter kan en vare (verdi) velges, noe som betyr at kun den varen er inkludert i beregningen.

Subtotalverdier fra pivottabellen brukes bare hvis de bruker funksjonen "auto" (bortsett fra når det er spesifisert i begrensningen, se Andre syntaks nedenfor).

### Andre syntaks

pivottabell har samme betydning som i den første syntaksen.

Begrensninger er en mellomromseparert liste. Bidrag kan siteres (enkelt sitat). Hele strengen må være omgitt av anførselstegn (doble anførselstegn), med mindre du refererer til strengen fra en annen celle.

En av oppføringene kan være datafeltnavnet. Datafeltnavnet kan utelates hvis pivottabellen inneholder kun ett datafelt, ellers må det være til stede.

Hver av de andre oppføringene spesifiserer en begrensning i formen Felt[element] (med bokstaver [ og ]), eller bare Element hvis elementnavnet er unikt innenfor alle feltene som brukes i pivottabellen.

Et funksjonsnavn kan legges til på formen felt[element;funksjon], hvilket betyr at kriteriene bare passer på delsumverdier som bruker denne funksjonen. De mulige funksjonsnavnene er Summer, Antall, Middel, Maks, Min, Produkt, Antall (kun tall), Stdav, Stdavp, Varians, og Variansp. Det skille ikke mellom store og små bokstaver.

## HYPERLENKE

Når du trykker på en celle som inneholder HYPERLENKE-funksjonen vil hypelenken åpnes.

Hvis du bruker den valgfrie CellValue-parameteren, finner formelen URL-en og viser deretter teksten eller tallet.

For å åpne en hyperlenken celle med tastaturet, velg cellen, trykk «F2» for å gå i redigeringsmodus, flytt pekeren foran hyperlenken, trykke «Shift+F10» og velg såÅpne hyperlenke.

#### Syntaks

HYPERLINK("URL" [; CellValue])

URL spesifiserer koblingsmålet. Den valgfrie CellValue-parameteren er teksten eller et tall som vises i cellen og vil bli returnert som resultat. Hvis CellValue-parameteren ikke er spesifisert, vises URL i celleteksten og returneres som resultat.

Tallet 0 returneres for tomme celler og matriseelementer.

#### Eksempel

=HYPERLINK("http://www.example.org") viser teksten "http://www.example.org" i cellen og kjører hyperkoblingen http://www.example .org når du klikker.

=HYPERLINK("http://www.example.org";"Klikk her") viser teksten "Klikk her" i cellen og kjører hyperkoblingen http://www.example.org når du klikker.

=HYPERLINK("http://www.example.org";12345) viser tallet 12345 og kjører hyperkoblingen http://www.example.org når den klikkes.

=HYPERLINK($B4) der celle B4 inneholder http://www.example.org. Funksjonen legger til http://www.example.org til URL-en til hyperkoblingscellen og returnerer den samme teksten som brukes som formelresultat.

=HYPERLINK("http://www.";"Klikk ") & "example.org" viser teksten Click example.org i cellen og kjører hyperkoblingen http://www.example .org når du klikker.

=HYPERLINK("#Ark1.A1";"Gå til toppen") viser teksten Gå til toppen og hopper til cellen Ark1.A1 i dette dokumentet.

=HYPERLINK("file:///C:/writer.odt#Specification";"Gå til Writer-bokmerke") viser teksten "Gå til Writer-bokmerke", laster det angitte tekstdokumentet og hopper for å bokmerke "Spesifikasjon".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") viser teksten "Open Documents folder" og viser mappeinnholdet ved å bruke standard filbehandling system.

## INDEKS (INDEX på engelsk)

INDEX returnerer en referanse, en verdi eller en matrise med verdier fra et referanseområde, spesifisert av rad- og kolonneindeksnummer eller matrise med rad og matrise med kolonner, indeksnumre, og en valgfri områdeindeks.

INDEX() returnerer en referanse hvis argumentet er én eller flere referanser. Når den brukes i en celle i formen =INDEX(), løses referansen og verdiene vises. Når INDEX() brukes i argumenter for andre funksjoner, =FUNCTION(INDEX()...), får funksjonen referansen sendt som ble returnert av INDEX(). Å returnere en referanse er forskjellig fra å returnere en rekke verdier for funksjoner som håndterer dem annerledes.

#### Syntaks

INDEKS(Referanse [; [Rad] [; [Kolonne] [; Område]]])

Referanse er en referanse, enten direkte eller ved å angi et områdenavn. Hvis referansen består av flere områder, må du omslutte listen over referanser eller områdenavn i parentes, eller enten bruke tilde (~) områdesammenkoblingsoperatoren eller definer et navngitt område med flere områder.

Rad (valgfritt) representerer raden eller matrisen av radindekser i referanseområdet som det skal returneres en verdi for. Ved null eller utelatt (ingen spesifikk rad) returneres alle refererte rader.

Kolonne (valgfritt) representerer kolonnen eller arrayen av kolonneindekser for referanseområdet som det skal returneres en verdi for. Ved null eller utelatt (ingen spesifikk kolonne) returneres alle refererte kolonner.

Hvis Rad, Kolonne eller begge er utelatt eller definert som matriser av indekser, må INDEX-funksjonen angis som en matrisefunksjon.

Område (valgfritt) representerer indeksen til underområdet hvis det refereres til et multippelområde, standard er 1.

#### Eksempel

{=INDEKS({1,3,5;7,9,10},{2;1},1)} returnerer en 2-rads matrise som inneholder 7 og 1. Radindeksen {2; 1} velg rad 2 og deretter rad 1. Kolonneindeks 1 velger den første kolonnen.

{=INDEX(D3:G12;{1;2;3;4},{3,1})} returnerer en 4 rader ganger 2 kolonner matrise. Radindeksmatrisen {1;2;3;4} velger rad 3 til 6 og {3;1} velger tredje (F) og første kolonne (D). Kolonne 1 og 3 i kildereferansen byttes i den resulterende matrisen.

=INDEKS(Priser;4;1) gir verdien fra rad 4 og kolonne 1 av databaseområdet angitt i Data → Angi som Priser.

=INDEX(SumX;4;1) returnerer verdien fra området SumX i rad 4 og kolonne 1 som definert i Ark - navngitt Områder og uttrykk – Definer.

{=INDEKS(A1:B6;1)} returnerer verdiene til den første raden i A1:B6. Skriv inn formelen som en matriseformel.

{=INDEKS(A1:B6;0;1)} returnerer verdiene til den første kolonnen i A1:B6. Skriv inn formelen som en matriseformel.

=INDEKS(A1:B6;1;1) angir verdien øverst i det venstre hjørnet av området A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} returnerer verdiene til det andre området C1:D6 i multippelområdet. Skriv inn formelen som en matriseformel.

Lignende emner

INDEX wiki side.

## INDIREKTE (INDIRECT på engelsk)

Gir referansen som er angitt ved en tekststreng. Du kan også bruke denne funksjonen for å finne området til den samsvarende strengen.

Denne funksjonen beregnes alltid på nytt hver gang en ny beregning skjer.

Av hensyn til interoperabilitet støtter funksjonene ADRESSE og INDIREKTE (INDIRECT på engelsk) en valgfri parameter for å angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT på engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, så blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, så blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT på engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

Når du åpner dokumenter fra ODF 1.0/1.1-format, vil ADRESSE-funksjonene som viser et arknavn som den fjerde parameteren skifte arknavnet til å bli den femte parameteren. En ny fjerde parameter med verdien 1 vil bli satt inn.

Når du lagrer et dokument i ODF 1.0/1.1-format, hvis ADRESSE-funksjoner har en fjerde parameter, vil denne parameteren bli fjernet.

Ikke lagre et regneark i det gamle ODF 1.0/1.1-formatet hvis ADRESSE-funksjonens nye fjerde parameter ble brukt med en verdi på 0.

Den INDIREKTE-funksjonen lagres uten konvertering til ODF 1.0/1.1-format. Hvis den andre parameteren var til stede, vil en eldre versjon av Calc returnere en feil for den funksjonen.

#### Syntaks

INDIRECT(Ref [; A1])

Referanse tilsvarer en referanse til en celle eller et område (i tekstform) som verdien skal returneres fra.

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

Hvis du åpner et Excel-regneark som bruker indirekte adresser beregnet fra strengfunksjoner, vil ikke arkadressene bli oversatt automatisk. Excel-adressen i INDIRECT("[filnavn]arknavn!"&B1) blir for eksempel ikke konvertert til Calc-adressen i INDIRECT("filnavn#arknavn."&B1).

#### Eksempel

=INDIREKTE(A1) er lik 100 hvis A1 inneholder C108 som en referanse og celle C108 inneholder en verdi på 100.

=SUMMER(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellene i området fra A1 opp til cellen hvis adresse er angitt ved rad 1 og kolonne 3. Det vil si: A1:C1 er oppsummert.

Lignende emner

INDIREKTE wikiside.

## KOLONNE (COLUMN på engelsk)

Returnerer kolonnenummeret til en cellereferanse. Hvis referansen er en celle, returneres kolonnenummeret til cellen; hvis parameteren er et celleområde, returneres de tilsvarende kolonnenumrene i en enkeltrads matrise hvis formelen er angittsom en matriseformel. Hvis COLUMN-funksjonen med en områdereferanseparameter ikke brukes for en matriseformel, bestemmes bare kolonnenummeret til den første cellen i området.

#### Syntaks

COLUMN([Referanse])

Referanse er referansen til en celle eller celleområde hvis første kolonnenummer finnes.

Hvis ingen referanse skrives inn, blir kolonnenummeret for cellen hvor formelen er skrevet inn funnet.LibreOffice Calc angir automatisk henvisningen til den gjeldende cellen.

#### Eksempel

=KOLONNE(A1) er lik 1. Kolonne A er den første kolonnen i tabellen.

=KOLONNE(C3:E3) er lik 3. Kolonne C er den tredje kolonnen i tabellen.

=KOLONNE(D3:G10) gir 4, fordi kolonne D er den fjerde kolonnen i tabellen, og KOLONNE-funksjonen ikke er brukt som en matriseformel. (I dette tilfellet brukes den første verdien i matrisen alltid som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver især 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneområder bare har et kolonnenummer, gjør det ingen forskjell om formelen blir brukt som en matriseformel.

==KOLONNE() gir 3 hvis formelen ble skrevet inn i kolonne C.

{=KOLONNE(Kanin)} gir enkeltradmatrisen (3; 4) hvis "Kanin" er det navngitte området (C1:D3).

## KOLONNER (COLUMNS på engelsk)

Gir antall kolonner i den oppgitte referansen.

#### Syntaks

KOLONNER(Matrise)

Matrise er referansen til et celleområde hvis totale antall kolonner skal finnes. Argumentet kan også være en enkelt celle.

#### Eksempel

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=KOLONNER(A1:C5) er lik 3. Henvisningen omfatter tre Kolonner.

=KOLONNER(Kanin) gir 2 hvisKanin er det navngitte området (C1:D3).

## OMRÅDER (AREAS på engelsk)

Gir antall individuelle områder som er med i et sammensatt område. Et dataområde kan bestå av èn enkelcelle eller et sammenhengende celleområde.

Funksjonen forventer et enkelt argument. Hvis du oppgir flere områder, må du sette dem inn i flere parenteser. Flere områder kan angis ved å bruke semikolon (;) som skillelinje, men dette blir automatisk konvertert til tilde (~)-operatoren. Tilden brukes til å slå sammen områder.

#### Syntaks

OMRÅDER(Referanse)

Referanse representerer referansen til en celle eller et celleområde.

#### Eksempel

=AREAS((A1:B3;F2;G1)) returnerer 3, da det er en referanse til tre celler og/eller områder. Etter inntasting blir dette konvertert til =AREAS((A1:B3~F2~G1)).

=OMRÅDER(Alt) gir 1 hvis du har angitt et område ved navn «Alt» under Data → Angi område..

## RAD

Returnerer radnummeret til en cellereferanse. Hvis referansen er en celle, returnerer den radnummeret til cellen. Hvis referansen er et celleområde, returnerer den tilsvarende radnummer i en én-kolonne Matrise hvis formelen er angitt som en matriseformel. Hvis ROW-funksjonen med en områdereferanse ikke brukes i en matriseformel, vil bare radnummeret til den første områdecellen bli returnert.

#### Syntaks

ROW([Referanse])

Referanse er en celle, et område eller navnet på et område.

Hvis du ikke angir en referanse, vil radnummeret for cellen hvor formlen er skrevet inn bli funnet.LibreOffice Calc angir automatisk referansen til den gjeldende cellen.

#### Eksempel

RAD(B3) gir 3, fordi referansen henviser til den tredje raden i tabellen.

{=RAD(D5:D8)} gir matrisen med enkeltkolonnen (5, 6, 7, 8), fordi den angitte referansen inneholder radene 5 til 8.

=RAD(D5:D8) gir 5 fordi REKKE-funksjonen ikke blir brukt som matriseformel og bare nummeret på den første raden i referansen returneres.

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver især 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneområder bare har et kolonnenummer, gjør det ingen forskjell om formelen blir brukt som en matriseformel.

=RAD() gir 3 hvis formelen ble skrevet inn i rad 3.

{=RAD(Kanin)} gir matrisen med enkeltkolonnen (1, 2, 3) hvis "Kanin" er det navngitte området (C1:D3).

## RADER (ROWS på engelsk)

Gir antall rader i en referanse eller tabell.

#### Syntaks

RADER(Matrise)

Matrise er referansen eller det navngitte området som totale antall rader skal oppdages for.

#### Eksempel

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=RADER(A10:B12) gir 3.

=RADER(Kanin) gir 3, hvis "Kanin" er det navngitte området (C1:D3).

## SAMMENLIGNE (MATCH på engelsk)

Gir den relative posisjonen til et element i en tabell, der elementet svarer til en viss verdi. Funksjonen gir posisjonen, som et nummer, til verdien funnet i søketabellen.

#### Syntaks

MATCH(Søk; LookupArray [; Type])

Søk er verdien som skal søkes etter i en rad eller en kolonne.

LookupArray er referansen det søkes etter. En oppslagsmatrise kan være en enkelt rad eller kolonne, eller en del av en enkelt rad eller kolonne.

Type kan ha verdiene 1, 0 eller -1. Hvis Type = 1 eller hvis denne valgfrie parameteren mangler, antas det at den første kolonnen i søkematrisen er sortert i stigende rekkefølge. Hvis Type = -1, antas det at kolonnen er sortert i synkende rekkefølge. Dette tilsvarer samme funksjon i Microsoft Excel.

Hvis Type = 0, finnes bare eksakte treff. Hvis søkekriteriet blir funnet mer enn én gang, returnerer funksjonen indeksen til den første samsvarende verdien. Bare hvis Type = 0 kan du søke etter regulære uttrykk (hvis aktivert i beregningsalternativer) eller jokertegn (hvis aktivert i beregningsalternativer).

Hvis Type = 1 eller den tredje parameteren mangler, returneres indeksen for den siste verdien som er mindre eller lik søkekriteriet. For Type = -1, returneres indeksen til den siste verdien som er større eller lik.

Søket støtter jokertegn eller regulære uttrykk. Med regulære uttrykk aktivert, kan du skrive inn "alle.*", for eksempel for å finne den første plasseringen av "alle" etterfulgt av tegn. Hvis du vil søke etter en tekst som også er et regulært uttrykk, må du enten bruke hvert regulært uttrykks metategn eller operator med et "\"-tegn, eller omslutte teksten i \Q...\E. Du kan pakke inn den automatiske evalueringen av jokertegn eller regulære uttrykk av og på i LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn .

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Eksempel

=MATCH(200;D1:D100) søker i området D1:D100, som er sortert etter kolonne D, etter verdien 200. Så snart denne verdien er nådd, vises tallet av raden den ble funnet i returneres. Hvis en høyere verdi blir funnet under søket i kolonnen, returneres nummeret til forrige rad.

## SHEET

Returnerer arknummeret til enten en referanse eller en streng som representerer et arknavn. Hvis du ikke angir noen parametere, er resultatet arknummeret til regnearket som inneholder formelen.

#### Syntaks

SHEET([Referanse])

Referanse er valgfri og er referansen til en celle, et område eller et arknavn.

#### Eksempel

=ARK(Ark2.A1) returnerer 2 hvis Ark2 er det andre arket i regnearkdokumentet.

=SHEET("Ark3") returnerer 3 hvis Ark3 er det tredje arket i regnearkdokumentet.

## VELG (CHOOSE på engelsk)

Bruker en indeks for å hente en verdi fra en liste med opptil 30 verdier.

#### Syntaks

VELG(Indeks; Verdi 1 [; Verdi 2 [; ... [; Verdi 30]]])

Indeks er en referanse eller et tall mellom 1 og 30, som angir hvilke verdier som skal tas fra listen.

Verdi 1, Verdi 2, ..., Verdi 30 er listen over verdier angitt som en referanse til en celle eller som individuelle verdier.

#### Eksempel

=VELG(A1; B1; B2; B3; "I dag"; "I går"; "I morgen"), gir for eksempel innholdet av celle B2 til A1 = 2; for A1 = 4 vil funksjonen returnere teksten "I dag".

Lignende emner

Funksjoner etter kategori