Contenido

# DIAS.LAB.INTL

Devuelve el número de días laborables que hay entre una fecha de inicio y una de finalización. Existen opciones para definir los días feriados y los correspondientes a los fines de semana. Se puede utilizar el parámetro (o cadena) opcional de fin de semana para definir los días de fin de semana (o los días no laborables de cada semana). Asimismo, de manera opcional, puede definirse una lista de feriados. Los días de fin de semana y los feriados definidos por el usuario no se cuentan como días laborables.

### Sintaxis

DIAS.LAB.INTL(FechaInicial; FechaFinal [; [ Fin de semana] [; Feriados ] ])

FechaInicial es la fecha a partir de la cual el cálculo se lleva a cabo. Si la fecha inicial es una día laborable, el día se incluye en el cálculo.

Fecha de finalización es la fecha en que el cálculo termina. Si la fecha de finalización es un día laborable, el día se incluye en el cálculo.

FinDeSemana es un parámetro opcional; es un número o una cadena que se emplea para especificar los días de la semana que se consideran fin de semana y no laborables. Los valores numéricos de FinDeSemana definen los días siguientes:

De 1 a 7 para fines de semana de dos días y 11 a 17 para fines de semana de un día.

Número | Fin de semana
--- | ---
1 u omitido | Sábado y domingo
2 | Domingo y lunes
3 | Lunes y martes
4 | Martes y miércoles
5 | Miércoles y jueves
6 | Jueves y viernes
7 | Viernes y sábado
11 | Domingo únicamente
12 | Lunes únicamente
13 | Martes únicamente
14 | Miércoles únicamente
15 | Jueves únicamente
16 | Viernes únicamente
17 | Sábado únicamente

La cadena FinDeSemana proporciona otra manera de definir los días no laborables semanales. Debe contener siete caracteres: ceros (0) por cada día laborable y unos (1) por cada día libre. Estos caracteres representan los días de la semana, comenzando por el lunes. Solo se permiten 0 y 1. «1111111» es una cadena no válida que no debe utilizarse. Para definir, a manera de ejemplo, el sábado y el domingo como días no laborables, puede emplearse «0000011».

Feriados es una lista opcional de fechas que deben contarse como días no laborables. La lista puede proporcionarse en forma de intervalo de celdas.

Cuando escriba fechas como parte de las fórmulas, las barras y los guiones que se usen como separadores de fechas se interpretarán como operadores aritméticos. Por este motivo, las fechas formateadas de este modo no se reconocen como tales y producen cálculos erróneos. Para evitar que las fechas se interpreten como parte de las fórmulas, utilice la fórmula FECHA —p. ej., FECHA(1954;7;20)—, o bien, entrecomíllela y ordene sus componentes según la notación ISO 8601 —p. ej., "1954-07-20"—. Evite utilizar formatos regionales de fechas, como «07/20/54», porque estos pueden conllevar a errores de cálculo si abre el documento en sistemas con una configuración regional distinta.

Es posible realizar una conversión sin ambigüedades de cronomarcadores en el formato ISO 8601 ampliado con separadores. Si se produjera un error #¡VALOR!, desmarque Generar error #¡VALOR! en LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Fórmula, apartado «Configuración detallada de cálculo», botón Detalles, cuadro de lista Conversión de texto a números.

Esta función ignora cualquier texto o celda vacía dentro de un intervalo de datos. Si sospecha que los resultados de esta función son erróneos, busque texto en los intervalos de datos. Para resaltar el contenido del texto en un intervalo de datos, utilice la funcionalidad de resalte de valores.

### Ejemplos

¿Cuántos días laborables hay entre el 15 de diciembre de 2016 y el 14 de enero de 2017? Sitúe la fecha inicial en C3 y la final en D3. Las celdas F3 a J3 contienen cinco (5) feriados para Navidad y Año Nuevo en formato de fecha: 24 de diciembre de 2016, 25 de diciembre de 2016, 26 de diciembre de 2016, 31 de diciembre de 2016 y 1 de enero de 2017.

=DIAS.LAB.INTL(C3;D3;;F3:J3) devuelve 21 días laborables con los fines de semana de manera predeterminada.

=DIAS.LAB.INTL(C3;D3;11;F3:J3) devuelve 24 días laborables con los domingos como únicos días de fin de semana.

Como alternativa, utilice la cadena «0000001» para definir solo el domingo como el día no laborable de cada semana.

=DIAS.LAB.INTL(C3;D3;"0000001";F3:J3) devuelve 24 días laborables con los domingos como únicos días de fin de semana.

Es posible pasar por alto los dos parámetros opcionales —Fin de semana y Feriados— y utilizar la función sin ellos:

=DIAS.LAB.INTL(C3;D3) devuelve 22 días laborables.

#### Información técnica

Esta función está disponible desde la versión 4.3 de LibreOffice

Esta función no forma parte de la norma Formato de Documentos Abierto para Aplicaciones de Oficina (OpenDocument), versión 1.3. Parte 4: formato de fórmulas recalculadas (OpenFormula). El espacio de nombres es

COM.MICROSOFT.NETWORKDAYS.INTL

Temas relacionados

NETWORKDAYS.INTL wiki page.

Funciones de fecha y hora

FECHA

SIFECHA

FECHANUMERO

DIA

DIAS

DIAS360

DIASENMES

DIASENAÑO

DOMINGOPASCUA

FECHA.MES

FIN.MES

HORA

ISLEAPYEAR

ISO.NUM.DE.SEMANA

MINUTO

MES

MONTHS

DIAS.LAB

DIAS.LAB.INTL

AHORA

SEGUNDO

NSHORA

HORANUMERO

HOY

DIASEM

NUM.DE.SEMANA

NUM.DE.SEMANA_EXCEL2003

NUM.DE.SEMANA_OOO

WEEKS

WEEKSINYEAR

DIA.LAB

DIA.LAB.INTL

AÑO

FRAC.AÑO

YEARS