Inhoud

# Matrixfuncties

Deze categorie bevat de matrixfuncties.

## Wat is een matrix?

Een matrix is een gekoppeld bereik van cellen op een werkblad met waardes. Een vierkant bereik van 3 rijen en 3 kolommen is een matrix van 3 x 3:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

De kleinst mogelijke matrix is een matrix van 1 x 2 of 2 x 1 met twee aangrenzende cellen.

## Wat is een matrixformule?

Een formule waarin de individuele waardes in een celbereik geëvalueerd worden, wordt aangeduid als een matrixformule. Het verschil tussen een matrixformule en andere formules is dat de matrixformule verschillende waardes tegelijk verwerkt, niet slechts één waarde.

Een matrixformule kan zowel verschillende waardes verwerken, als verschillende waardes retourneren. De resultaten van een matrixformule zijn ook een matrix.

U hoeft geen formule op elke individuele cel of waarde toe te passen om de waardes in de individuele cellen in bovenstaande matrix met 10 te vermenigvuldigen. In plaats daarvan kunt u één enkele matrixformule gebruiken. Selecteer een bereik van 3 x 3 cellen op een ander gedeelte van het werkblad, voer de formule =10*A1:C3 in en bevestig deze invoer met de toetscombinatie CommandoCtrl+Shift+Enter. Het resultaat is een 3 x 3-matrix waarin de individuele waardes in het celbereik (A1:C3) zijn vermenigvuldigd met de factor 10.

Behalve vermenigvuldiging kunt u ook andere operatoren op het referentiebereik (een matrix) gebruiken. In LibreOffice Calc kunt u optellen (+), aftrekken (-), vermenigvuldigen (*), delen (/), exponenten gebruiken (^), samenvoegen (&) en vergelijken (=, <>, <, >, <=, >=). De operatoren kunnen op elke afzonderlijke waarde in het celbereik toegepast worden en geven het resultaat als een matrix als de matrixformule is ingevoerd.

Vergelijkingsoperatoren in een matrixformule behandelen lege cellen op dezelfde wijze als in een normale formule, hetgeen betekent of als een nul of als een tekenreeks. Als bijvoorbeeld de cellen A1 en A2 leeg zijn, zullen de matrixformules {=A1:A2=""} en {=A1:A2=0} beide een 1 kolom-/2 rijen matrix van cellen teruggeven met WAAR.

### Wanneer gebruikt u matrixformules?

Gebruik matrixformules als u berekeningen moet herhalen met verschillende waardes. Als u de berekeningsmethode later wilt wijzigen, hoeft u alleen de matrixformule bij te werken. Wilt u een matrixformule toevoegen, dan selecteert u het hele matrixbereik en moet u vervolgens de vereiste wijzigingen in de matrixformule aanbrengen.

Matrixformules helpen ook geheugenruimte te besparen als meerdere waardes moeten worden berekend, omdat zij het geheugen niet bijzonder intensief belasten. Matrices zijn ook een essentieel hulpmiddel voor het uitvoeren van complexe berekeningen, omdat u meerdere celbereiken in berekeningen kunt opnemen. LibreOffice heeft verschillende wiskundige functies voor matrices, zoals de functie MULTINOMIAAL voor het vermenigvuldigen van matrices of de functie SUMPRODUCT voor het berekenen van de scalaire producten van twee matrices.

## Matrixformules in LibreOffice Calc gebruiken

### Impliciete kruising van matrixformules

U kunt ook een "normale" formule maken waarin het referentiebereik, zoals parameters, een matrixformule aangeeft. Deze formule is ook bekend als "impliciete intersectie" van matrixformule. Het resultaat wordt verkregen uit het snijpunt van het referentiebereik en de rijen of kolommen waarin de formule voorkomt. Als er geen snijpunt is of als het bereik bij het snijpunt meerdere rijen of kolommen beslaat, wordt een #WAARDE! foutmelding verschijnt. Het volgende voorbeeld illustreert dit concept:

Plaats in de bovenstaande tabel de matrixformule in D1:

{=A1:A3 + 100}

Cellen D1, D2, D3 hebben respectievelijk de waardes 107, 195, 105.

Vul onderstaande formule in E2, niet als matrixformule, in.

=A1:A3 + 100

Cellen E1 en E3 zijn leeg, cel E2 heeft waarde 195. Dit is het impliciete snijpunt van matrixformules.

Voeg onderstaande formule in E4 in, zoals in E2.

=A1:A3 + 100

Cel E4 toont #WAARDE!. Rij 4 valt buiten het bereik A1:A3 van de formule.

### Matrixformules maken

Als u een matrixformule maakt met behulp van de Functie-Assistent, moet u het aankruisvakje Matrix telkens selecteren zodat de resultaten in een matrix geretourneerd worden. Anders wordt alleen de waarde geretourneerd in de cel linksboven van de matrix die berekend wordt.

Wanneer u een matrixformule rechtstreeks in een cel invoert, moet u de toetscombinatie Shift+CommandoCtrl+Enter gebruiken, in plaats van de Enter-toets. Alleen dan wordt de formule een matrixformule.

Matrixformules worden tussen accolades weergegeven in LibreOffice Calc. U kunt geen matrixformules maken door de accolades handmatig in te voeren.

De cellen in een resultatenmatrix worden automatisch beveiligd tegen wijzigingen. U kunt de matrixformule echter bewerken, verwijderen of kopiëren door het volledige matrixcelbereik te selecteren.

### Het gebruik van in-regelige matrixconstanten in formules

Calc ondersteunt in-regelige matrix-/arrayconstanten in formules. Een in-regelige matrix wordt omsloten door accolades '{' en '}'. Elementen kunnen zowel een getal (inclusief negatieve), een logische constante (WAAR, ONWAAR) of een letterlijke tekenreeks zijn. Niet-constante expressies zijn niet geldig. Matrices kunnen worden ingevoerd met één of meer rijen en één of meer kolommen. Alle rijen moeten bestaan uit hetzelfde aantal elementen en alle kolommen moeten bestaan uit hetzelfde aantal elementen.

Het scheidingsteken voor kolommen (dat elementen in een rij scheidt) en het scheidingsteken voor rijen zijn van afhankelijk van de taal en taalinstelling. Maar in de help worden respectievelijk ';' puntkomma en '|' sluisteken gebruikt als scheidingsteken voor kolommen en rijen. Bijvoorbeeld, in de Engelse taalinstelling wordt de ',' komma gebruikt als scheidingsteken voor kolommen en ';' puntkomma als scheidingsteken voor rijen.

U kunt het scheidingsteken voor kolommen en rijen zien en wijzigen in LibreOffice - VoorkeurenExtra - Opties - LibreOffice Calc - Formule - Scheidingstekens.

Matrices kunnen niet worden genest.

Voorbeelden:

={1;2;3}

Een matrix met één rij bestaande uit de drie getallen 1, 2 en 3.

Als u deze matrixconstante wilt invoeren, selecteert u drie cellen achter elkaar en typt u de formule={1;2;3} met accolades en puntkomma's en druk vervolgens op CommandoCtrl+Shift+Enter.

={1;2;3|4;5;6}

Een matrix met twee rijen en drie waardes in elke rij.

={0;1;2|ONWAAR;WAAR;"twee"}

Een gemengde gegevensmatrix.

=SIN({1;2;3})

Ingevoerd als een matrixformule, geeft als resultaat de drie SIN-berekeningen met de argumenten 1, 2 en 3.

### Matrixformules bewerken

1. Selecteer het celbereik of de matrix die de matrixformule bevat. Om de hele matrix te selecteren, plaatst u de celcursor binnen het matrixbereik en drukt u vervolgens op CommandoCtrl + /, waarbij / de deeltoets op het numerieke toetsenbord is.

2. Druk op F2 of plaats de cursor op de invoerregel. Via beide handelingen kunt u de formule bewerken.

3. Na het aanbrengen van wijzigingen drukt u op CommandoCtrl+Shift+Enter.

U kunt de afzonderlijke delen van een matrix opmaken. Zo kunt u de kleur van het lettertype wijzigen. Selecteer een celbereik en wijzig dan het gewenste kenmerk.

### Matrixformules verwijderen

1. Selecteer het celbereik of de matrix die de matrixformule bevat. Om de hele matrix te selecteren, plaatst u de celcursor binnen het matrixbereik en drukt u vervolgens op CommandoCtrl + /, waarbij / de deeltoets op het numerieke toetsenbord is.

2. Druk op Delete om de matrixinhoud te verwijderen, inclusief de matrixformule, of druk op Backspace en dit opent het dialoogvenster Inhoud verwijderen. Selecteer Formule of Alles verwijderen en klik op OK.

### Matrixformules kopiëren

1. Selecteer het celbereik of de matrix waarin de matrixformule zich bevindt.

2. Druk op F2 of plaats de cursor op de invoerregel.

3. Kopieer de formule naar de invoerregel door te drukken op CommandoCtrl + C.

4. Selecteer een cellenbereik waar de matrixformule ingevoegd moet worden en druk dan op F2 of plaats de cursor in de invoerregel.

5. Plak de formule in de geselecteerde ruimte door te drukken op CommandoCtrl+V en bevestig dit door te drukken op CommandoCtrl+Shift+Enter. Het geselecteerde bereik bevat nu de matrixformule.

### Een matrixbereik aanpassen

U bewerkt de uitvoermatrix als volgt:

1. Selecteer het celbereik of de matrix waarin de matrixformule zich bevindt.

2. Rechts onderaan de selectie ziet u het pictogram, waarmee u op het bereik met behulp van de muis kunt vergroten of verkleinen.

Wanneer u het matrixbereik aanpast, wordt de matrixformule niet automatisch aangepast. U wijzigt alleen het bereik waarin het resultaat zal verschijnen.

Door de toets CommandoCtrl ingedrukt te houden, kunt u een kopie van de matrixformule maken in het gekozen bereik.

### Voorwaardelijke matrixberekeningen

Een voorwaardelijke matrixberekening is een matrix of matrixformule die de functie ALS() of KIES() bevat. Het argument met de voorwaarde in de formule, is een gebiedsverwijzing of een matrixresultaat.

In het volgende voorbeeld wordt de test >0 van de formule {=ALS(A1:A3>0;"ja";"nee")} toegepast op elke cel in het bereik A1:A3, en wordt het resultaat naar de corresponderende cel gekopieerd.

| A | B (formule) | B (resultaat)
1 | 1 | {=ALS(A1:A3>0;"ja";"nee")} | ja
2 | 0 | {=ALS(A1:A3>0;"ja";"nee")} | nee
3 | 1 | {=ALS(A1:A3>0;"ja";"nee")} | ja

De volgende functies bieden afgedwongen matrixverwerking: CORRELATIE, COVARIANTIE, VOORSPELLEN, F.TOETS, SNIJPUNT, DETERMINANT.MAT, INVERSEMAT, PRODUCTMAT, MODUS, PEARSON, KANS, R.KWADRAAT, RICHTING, STAND.FOUT.YX, SOMPRODUCT, SOM.X2MINY2, SOM.X2PLUSY2, SOM.XMINY.2, TTOETS. Als u gebiedsverwijzingen als argumenten gebruikt wanneer u een van de functies aanroept, gedragen ze zich als matrixfuncties. In de volgende tabel vindt u een voorbeeld van afgedwongen matrixverwerking:

| A | B (formule) | B (resultaat) | C (afgedwongen matrixformule) | C (resultaat)
1 | 1 | =A1:A2+1 | 2 | =SOMPRODUCT(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SOMPRODUCT(A1:A2+1) | 5
3 |  | =A1:A2+1 | #WAARDE! | =SOMPRODUCT(A1:A2+1) | 5

## DETERMINANT.MAT

Geeft de matrixdeterminant van een matrix. Deze functie retourneert een waarde in de huidige cel; het is niet nodig een bereik voor de resultaten te definiëren.

#### Syntaxis

DETERMINANT.MAT(Matrix)

Matrix staat voor een vierkante matrix waarin de determinanten worden gedefinieerd.

Boven aan deze pagina vindt u een algemene inleiding tot het gebruik van matrixfuncties.

Meer uitleg bovenaan deze pagina.

## EENHEIDSMAT

Geeft de vierkante eenheidsmatrix van een bepaalde grootte. De eenheidsmatrix is een vierkante matrix waarvan de elementen van de hoofddiagonaal gelijk zijn aan 1 en alle andere matrixelementen gelijk zijn aan 0.

#### Syntaxis

EENHEIDSMAT(Dimensie)

Dimensie verwijst naar de grootte van de matrixeenheid.

Boven aan deze pagina vindt u een algemene inleiding tot matrixfuncties.

#### Voorbeeld

Selecteer een vierkant bereik in het werkblad, bijvoorbeeld van A1 tot E5.

Selecteer de functie EENHEIDSMAT zonder de selectie van het bereik op te heffen. Markeer het keuzevak Matrix. Voer de gewenste dimensies voor de matrixeenheid in, in dit geval 5 en klik op OK.

U kunt ook de formule =EENHEIDSMAT(5) in de laatste cel van het geselecteerde bereik (E5) invoeren en op Shift + Command + EnterShift + Ctrl + Enter.

U ziet nu een eenheidsmatrix met een bereik van A1:E5.

Meer uitleg bovenaan deze pagina.

## GROEI

Berekent de punten van een exponentiële trend in een matrix.

#### Syntaxis

GROEI(Gegevens Y [; [ Gegevens X ] [; [ NieuweGegevens X ] [; Functietype ] ] ])

Gegevens Y vertegenwoordigt de gegevensmatrix Y.

Gegevens X (optioneel) vertegenwoordigt de gegevensmatrix X.

NieuweGegevens X (optioneel) vertegenwoordigt de matrix van de X-gegevens, die worden gebruikt voor het herberekenen van waardes.

Functietype (optioneel). Als Functietype = 0 zullen functies in de vorm y = m^x worden berekend. Anders worden y = b*m^x-functies berekend.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Deze functie geeft een matrix terug en wordt op dezelfde wijze afgehandeld als de andere matrixfuncties. Selecteer een bereik waar u wilt dat de antwoorden verschijnen en selecteer de functie. Selecteer Gegevens Y. Voer enkele andere parameters in, markeer Matrix en klik op OK.

## INTERVAL

Bepaalt de frequentieverdeling in een matrix met één kolom. De functie telt hoeveel waardes in de gegevensmatrix binnen de matrix Data liggen die door de matrix Klassen gegeven worden.

#### Syntaxis

INTERVAL(Gegevens; Klassen)

Gegevens staat voor de verwijzing naar de waardes die geteld moeten worden.

Klassen staat voor de matrix van de grenswaardes.

Deze functie negeert elke tekst of lege cel binnen een gegevensbereik. Als u verkeerde resultaten van deze functie vermoedt, zoek dan naar tekst in de gegevensbereiken. Gebruik de functie waarde markeren om tekstinhoud in een gegevensbereik te markeren.

Boven aan deze pagina vindt u een algemene inleiding tot matrixfuncties.

#### Voorbeeld

In de volgende tabel staan in kolom A ongesorteerde meetwaarden. Kolom B bevat de bovengrens die u hebt ingevoerd voor de klassen waarin u de gegevens in kolom A wilt opdelen. Met inachtneming van de grenswaarde die is ingevoerd in B1 geeft de functie INTERVAL het aantal meetwaardes terug dat kleiner of gelijk is aan 5. Als de bovengrens in B2 10 is, geeft de functie INTERVAL als tweede resultaat het aantal meetwaardes dat groter is dan 5 en kleiner of gelijk is aan 10 terug. De tekst ">25", die u hebt ingevoerd in B6, is slechts voor verwijzingsdoeleinden.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Selecteer een bereik van één kolom waarin de interval moet worden ingevoerd, met inachtneming van de klassengrenzen. U moet één veld meer selecteren dan de hoogste klassenwaarde. Selecteer in dit voorbeeld het bereik C1:C6. Roep de functie INTERVAL op met de Functie-Assistent. Selecteer het bereik Gegevens in (A1:A11) en dan het bereik Klassen waarin u de klassengrenzen hebt ingevoerd, (B1:B6). Markeer het keuzevakje Matrix en klik op de knop OK. U zult de telling van de interval zien in het bereik C1:C6.

Meer uitleg bovenaan deze pagina.

## INVERSEMAT

Geeft de inverse matrix.

#### Syntaxis

INVERSEMAT(Matrix)

Matrix staat voor een vierkante matrix die omgekeerd moet worden.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Selecteer een vierkant bereik en selecteer dan INVERSEMAT. Selecteer de uitvoermatrix, selecteer het veld Matrix en klik op OK.

## LIJNSCH

Geeft een tabel met statistieken terug voor een rechte lijn die het beste overeenkomt met de gegevensverzameling.

#### Syntaxis

LIJNSCH(Gegevens_Y [; Gegevens_X [; Lineairtype [; Statistieken]]])

Gegevens_Y is één enkele rij of kolombereik die de Y-coördinaten in een verzameling gegevenspunten specificeert.

Gegevens_X is een overeenkomende enkele rij of kolombereik dat de the X-coördinaten specificeert. Als Gegevens_X wordt weggelaten, wordt standaard 1, 2, 3, ..., n ingevuld. Indien er meer dan één verzameling variabelen is kan Gegevens_X een bereik zijn met meerdere overeenkomende rijen of kolommen.

LIJNSCH vindt een rechte lijn y = a + bx die het beste overeenkomt met de gegevens, met behulp van lineaire regressie (de "least squares"-methode). Met meer dan één set van variabelen is de rechte lijn in de vorm y = a + b1x1 + b2x2 ... + bnxn.

Als Lineairtype ONWAAR is wordt de gevonden rechte lijn gedwongen door het punt van oorsprong te gaan (de constante a is nul; y = bx). Indien weggelaten, gaat Lineairtype standaard naar WAAR (de lijn wordt niet gedwongen dor het punt van oorsprong te gaan).

Als Statistieken wordt weggelaten of ONWAAR is wordt alleen de bovenste lijn van de tabel met statistieken teruggegeven. Indien WAAR wordt de gehele tabel teruggegeven.

LIJNSCH geeft een tabel (matrix) van statistieken zoals hieronder terug en moet worden ingevoerd als een matrixformule (door bijvoorbeeld CommandoCtrl+Shift+Enter te gebruiken, in plaats van alleen Enter).

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Deze functie geeft een matrix terug en wordt op dezelfde wijze afgehandeld als de andere matrixfuncties. Selecteer een bereik waar u wilt dat de antwoorden verschijnen en dan de functie. Selecteer Gegevens_Y. Voer enkele andere parameters in, als u dat wilt Selecteer Matrix en klik op OK.

De door het systeem (als Statistieken = 0) teruggegeven resultaten zullen tenminste de helling van de regressielijn en de kruising daarvan met de Y-as weergeven. Indien Statistieken niet gelijk is aan 0 zullen andere resultaten worden weergegeven.

### Andere LIJNSCH-resultaten:

Kijk eens naar de volgende voorbeelden:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | LIJNSCH-waarde |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #NB
5 | 7 | 12 | 108 |  | 13,21 | 4 | #NB
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #NB
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Kolom A bevat verschillende X1-waarden, kolom B verschillende X2-waardes en kolom C de Y-waardes. U heeft deze waarden al in uw werkbladen ingevoerd. U hebt nu E2:G6 in het werkblad ingesteld en de Functie-Assistent geactiveerd. Het vakje Matrix in de Functie-Assistent moet geselecteerd zijn, anders werkt de functie LIJNSCH niet. Selecteer daarna de volgende waarden in het werkblad (of voer ze via het toetsenbord in).

Gegevens_Y is C2:C8

Gegevens_X is A2:B8

Lineairtype en Statistieken zijn beide ingesteld op 1.

Zodra u op OK klikt, vult LibreOffice Calc het bovenstaande voorbeeld in met de LIJNSCH-waardes zoals in het voorbeeld weergegeven wordt.

De formule in de Formulebalk komt overeen met elke cel van de matrix LIJNSCH {=LIJNSCH(C2:C8;A2:B8;1;1)}.

Dit staat voor de berekende LIJNSCH-waardes:

E2 en F2: helling m van de regressielijn y=b+m*x voor de x1- en x2-waardes. De waarden worden in omgekeerde volgorde gegeven; dat betekent de helling voor x2 in E2 en de helling voor x1 in F2.

G2: Doorsnede b met de y-as.

E3 en F3: De standaardfout van de stijgingswaarde.

G3: De standaardfout van het snijpunt

E4: R.KWADRAAT

F4: De standaardfout van de regressie die voor de Y-waarde berekend is.

E5: De F-waarde uit de variantieanalyse.

F5: De vrijheidsgraden van de variantieanalyse.

E6: De som van de gekwadrateerde afwijking van de geschatte Y-waardes uit hun lineaire gemiddelde.

F6: De som van de gekwadrateerde afwijking van de geschatte Y-waarde uit de gegeven Y-waardes.

Meer uitleg bovenaan deze pagina.

## LOGSCH

Deze functie berekent de aanpassing van de ingevoerde gegevens als een exponentiële regressieboog (y=b*m^x).

#### Syntaxis

LOGSCH(Gegevens Y [; Gegevens X [; FunctieType [; Statistieken]]])

Gegevens Y vertegenwoordigt de gegevensmatrix Y.

Gegevens X (optioneel) vertegenwoordigt de gegevensmatrix X.

Functietype (optioneel). Als Functietype = 0 zullen functies in de vorm y = m^x worden berekend. Anders worden y = b*m^x-functies berekend.

Parameter (optioneel). Als Parameter=0, wordt alleen de regressiecoëfficiënt berekend.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Zie LIJNSCH. Er wordt echter geen som van de kwadraten geretourneerd.

## PRODUCTMAT

Berekent het matrixproduct van twee matrices. Het aantal kolommen voor matrix 1 moet overeenkomen met het aantal rijen voor matrix 2. De vierkante matrix heeft net zoveel rijen als kolommen.

#### Syntaxis

PRODUCTMAT(Matrix1; Matrix2)

Matrix1 vertegenwoordigt de eerste matrix die in het matrixproduct wordt gebruikt.

Matrix2 vertegenwoordigt de tweede array met hetzelfde aantal rijen.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Selecteer een vierkant bereik. Kies de PRODUCTMAT-functie. Selecteer Matrix1, selecteer vervolgens Matrix2. Schakel met behulp van de Functie-assistent, het selectievak Matrix in. Klik op OK. De uitvoermatrix verschijnt in het eerste geselecteerde bereik..

## SOM.X2MINY2

Geeft de som van het verschil tussen de kwadraten van overeenkomende waardes in twee matrices.

#### Syntaxis

SOM.X2MINY2(MatrixX; MatrixY)

MatrixX vertegenwoordigt de eerste matrix, waarvan de elementen tot de tweede macht moeten verheven worden en dan worden opgeteld.

MatrixY vertegenwoordigt de tweede matrix, waar van de elementen de wortel moet worden berekend en dan worden afgetrokken.

Meer uitleg bovenaan deze pagina.

## SOM.X2PLUSY2

Geeft de som van de som van kwadraten van overeenkomende waardes in twee matrices.

#### Syntaxis

SOM.X2PLUSY2(MatrixX; MatrixY)

MatrixX vertegenwoordigt de eerste matrix, waarvan de elementen tot de tweede macht moeten verheven worden en dan worden opgeteld.

MatrixY vertegenwoordigt de tweede matrix, waar van de elementen de wortel moet worden berekend en dan worden afgetrokken.

Meer uitleg bovenaan deze pagina.

## SOM.XMINY.2

Telt de kwadraten op van de variantie tussen overeenkomstige waardes in twee matrices.

#### Syntaxis

SOM.XMINY.2 (MatrixX; MatrixY)

MatrixX vertegenwoordigt de eerste matrix waarvan de elementen moeten worden afgetrokken en waarvan de wortel moet worden berekend.

MatrixY vertegenwoordigt de eerste matrix waarvan de elementen moeten worden afgetrokken en waarvan de wortel moet worden berekend.

Meer uitleg bovenaan deze pagina.

## SOMPRODUCT

Vermenigvuldigt overeenkomende elementen in de gegeven matrices, en geeft de som van die producten.

#### Syntaxis

SOMPRODUCT(Matrix 1[; Matrix 2;][...;[Matrix 255]])

Matrix 1[; Matrix 2;][...;[Matrix 255]] vertegenwoordigen matrices waarvan de overeenkomstige elementen moeten worden vermenigvuldigd.

Ten minste één matrix moet deel uitmaken van de argumentenlijst. Als er maar één matrix is opgegeven, worden alle matrix-elementen opgeteld. Als er meer dan één matrix is opgegeven, moeten ze allemaal even groot zijn.

#### Voorbeeld

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SOMPRODUCT(A1:B3;C1:D3) geeft 397 terug.

Berekening: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

U kunt SOMPRODUCT gebruiken om het scalaire product van twee vectoren te berekenen.

SOMPRODUCT geeft één getal en de functie hoeft niet als een matrixfunctie ingevoerd te worden.

Meer uitleg bovenaan deze pagina.

## TRANSPONEREN

Transponeert de rijen en kolommen van een matrix.

#### Syntaxis

TRANSPONEREN(Matrix)

Matrix staat voor de matrix in het werkblad die getransponeerd moet worden.

Boven aan deze pagina vindt u een algemene inleiding tot het gebruik van matrixfuncties.

#### Voorbeeld

Selecteer, in het werkblad, het bereik waarin de getransponeerde matrix moet verschijnen. Indien de originele matrix n rijen en m kolommen had, moet uw geselecteerde bereik tenminste m rijen en n kolommen hebben. Voer dan de formule direct in, selecteer de originele matrix en druk op Shift+Command+EnterShift+Ctrl+Enter. Of, als u de Functie-Assistent gebruikt, markeer het keuzevak Matrix. De getransponeerde matrix verschijnt in het geselecteerde doelbereik en wordt automatisch beveiligd tegen wijzigingen.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

De bovenstaande tabel bevat 2 rijen en 4 kolommen. Om deze te transponeren moet u 4 rijen en 2 kolommen selecteren. Als u de bovenstaande tabel wilt transponeren naar het bereik A7:B10 (4 rijen en 2 kolommen) moet u het volledige bereik selecteren en dan het volgende invoeren:

TRANSPONEREN(A1:D2)

Vervolgens zorg ervoor dat u het invoert als matrixformule met Shift+Command+EnterShift+Ctrl+Enter. Het resultaat is als volgt:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

## TREND

Geeft waardes op basis van een lineaire trend.

#### Syntaxis

TREND(Gegevens Y [; Gegevens X [; NieuweGegevens X [; Lineairtype]]])

Gegevens Y vertegenwoordigt de gegevensmatrix Y.

Gegevens X (optioneel) vertegenwoordigt de gegevensmatrix X.

NieuweGegevens X (optioneel) vertegenwoordigt de matrix van de X-gegevens, die worden gebruikt voor het herberekenen van waardes.

Lineairtype (optioneel). Als Lineairtype = 0 worden lijnen berekend door het nulpunt. Anders worden daarbuiten vallende lijnen ook berekend. Standaard is Lineairtype <> 0.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

Meer uitleg bovenaan deze pagina.

#### Voorbeeld

Selecteer een werkbladbereik waarin de trendgegevens zullen verschijnen. Selecteer de functie. Voer de uitvoergegevens in of selecteer ze met de muis. Selecteer het veld Matrix en klik op OK. De trendgegevens die uit de uitvoergegevens berekend zijn, worden weergegeven.

Verwante onderwerpen

Functies per categorie