Innhald
Innhaldsliste 🔎︎

# Tekstfunksjonar

Denne bolken handlar om Tekst-funksjonane.

For å bruka denne funksjonen …

Set inn → Funksjon → Kategori Tekst

## Bruk av doble hermeteikn i formlar

Skal du ha med ein tekststreng i ein formel, skriv du han mellom doble hermeteikn ("). Dette gjer at Calc tek med teksten i strengen utan å gjera noko meir med han. Såleis vi formelen "Hallo verda" visa teksten Hallo verda i cella utan hermeteikna.

Den meir komplekse formelen =KJEDA.SAMAN("Livet er enkelt, "; "men vi insisterer på å gjera det komplisert "; "(Konfutse).") vil kjeda saman dei tre enkeltstrengane i doble hermeteikn til Livet er enkelt, men vi insisterer på å gjera det komplisert (Konfutse).

Skal du visa eit verkeleg dobbelthermeteikn i ein streng i ein formel, kan du gjera det på to måtar:

1. Du kan «Escape» det doble hermeteiknet med eit dobbelt hermeteikn, altså setja eit dobbelt hermeteikn framføre det doble hermeteiknet. Calc vil då handsama det ekstra hermeteiknet som eit hermeteikn. Såleis vil formelen="Namnet mitt er ""Ole Olsen""." gje strengen Namnet mitt er "Ole Olsen". Eit anna enkelt eksempel er formelen =UNICODE("""") som returnerer 34, desimalverdien av hermeteiknet i Unicode (U+0022) – her viser det det første og det fjerde doble hermeteiknet byrjinga og slutten av strengen, medan det andre doble hermeteiknet «escapes» det tredje.

2. Du kan bruka TEIKNKODE-funksjonen eller UNITEIKN-funksjonen for å setja inn eit dobbelt hermeteikn. For eksempel vil formelen =UNITEIKN(34) & "Redderen i rugen" & UNITEIKN(34) & " er ei kjent bok av J. D. Salinger." visa strengen "Redderen i rugen" er ei kjent bok av J. D. Salinger.

Ver merksam på at autorettingsfunksjonen i Calc kan endra doble hermeteikn. Autorettinga skal ikkje endra dei doble hermeteikna i formelceller, men kan endra dei som vert brukte i celler som ikkje er formelceller og inneheld tekst. Viss du for eksempel kopierer ein streng som er omgjeve av ei anna form for typografiske doble hermeteikn, for eksempel venstre doble hermeteikn (U+201C) (“) og høgre doble hermeteikn (U+201D) (”), og deretter limer inn i ei formelcelle, kan du få ei feilmelding. Opna området Doble sitatteikn i Verktøy → Autoretting → Innstillingar for autoretting → Lokaliserte val for å bestemma kva teikna som skal brukast til å retta start- og slutttypografiske doble hermeteikn. Fjern avmerkinga for Erstatt for å slå av funksjonen.

## ARABISK

Returnerer talverdien, som tekst, som svarar til eit romartal.

## ASC

Konverterer dobbelt-byte (fullbreidde) teikn til enkelt-byte (halvbreidde) ASCII- og katakana-teikn.

## JIS

Konverterer enkelt-byte (halv-breidde) ASCII- eller katakana-teikn til dobbelt-byte (fullbreidde) teikn.

## REGEX

Finn og trekk ut eller bytar ut tekst ved hjelp av regulære uttrykk.

## ROMARTAL

Konverterer eit tal til eit romartal. Verdiområdet må vera mellom 0 og 3999. Ein enklare modus kan brukast i området frå 0 til 4.

## VERDI

Konverterer strengrepresentasjonen av eit tal til numerisk form. Viss strengen er ein gyldig dato, klokkeslett eller dato-klokkeslett, vert det serielle dato-klokkeslett-talet returnert.

### NETTENESTE

Hent innhald frå nettet via ein URI.

### FILTERXML

Bruk eit XPath-uttrykk på eit XML-dokument.

### NETTADRESSEKODE

Returnerer ein streng med dekoda nettadresse.

## BAHTTEKST (BAHTTEXT på engelsk)

Gjer eit tal om til Thaitekst, inklusive Thaivalutanamn.

#### Syntaks

BAHTTEKST(Tal)

Tal er eit vilkårleg tal. «Baht» vert lagt til den heile delen av talet, og «Satang» vert lagt til desimaldelen av talet.

#### Eksempel

=BAHTTEKST(12,65) returnerer ein streng i Thaiteikn som omsett vert «Tolv Baht og sekstifem Satang».

#### Teknisk informasjon

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

COM.MICROSOFT.BAHTTEXT

## BASE

Gjer om eit positivt heiltal til ein tekst i eit bestemt talsystem. Tala 0-9 og bokstavane A-Z vert brukte.

#### Syntaks

BASE(Tal; Grunntal[;Minimumslengd])

Tal er det positive heiltalet som skal konverterast.

Base indikerer basen for talsystemet. Det kan vara alle positive heiltal mellom 2 og 36.

Minimumlengd (valfri) bestemmer den minste lengda på teiknsekvensen som skal lagast. Dersom teksten er kortare enn denne minstelengda, vert det lagt til nullar til venstre i strengen.

#### Eksempel

=BASIS(17; 10; 4) returnerer 0017 i det desimale talsystemet (titalssystemet).

=BASIS(17; 2) returnerer 10001 i det binære talsystemet.

=BASIS(255; 16; 4) returnerer 00FF i det heksadesimale talsystemet.

#### Sjå også

DESIMAL

## BYT.UT (SUBSTITUTE på engelsk)

Byter ut ein tekst med ein ny tekst i ein streng.

#### Syntaks

BYT.UT("Tekst"; "SøkjeTekst"; "NyTekst"[; Førekomst])

Tekst er teksten der tekstsegmenta skal bytast ut.

SøkTekst er tekstsegmentet som skal byttast ut (fleire gongar).

NyTekst er teksten som skal erstatte tekstsegmentet.

Førekomst (valfri) indikerer kva førekomst av søkjeteksten som skal byttast ut. Dersom denne parameteren manglar, vert alle førekomstane bytt ut.

#### Eksempel

=BYT.UT("123123123";"3";"abc") returnerer 12abc12abc12abc

=BYT.UT("123123123";"3";"abc";2) returnerer 12312abc123

## DESIMAL (DECIMAL på engelsk)

Konverterer tekst med teikn frå eit talsystem til eit positivt heiltal med det gjevne grunntalsystemet. Grunntalet må vera i området 2 til 36. Mellomrom og tabuleringar vert ignorerte. Feltet Tekst skil ikkje mellom små og store bokstavar.

Viss basen er 16 vert eit innleiande x eller X, 0x eller 0X eller avsluttande h eller H ignorerte. Viss basen er 2, vert avsluttande b eller B ignorert. Andre teikn som ikkje høyrer til i talsystemet vil generera ein feil.

#### Syntaks

DESIMAL("Tekst"; Base)

Tekst er teksten som skal konverterast.

Base indikerer basen for talsystemet. Det kan vara alle positive heiltal mellom 2 og 36.

#### Eksempel

=DESIMAL("17"; 10) returnerer 17.

=DESIMAL("FACE"; 16) returnerer 64206.

=DESIMAL("0101"; 2) returnerer 5.

#### Sjå også

BASE

## ERSTATT (REPLACE på engelsk)

Byter ut ein del av ein tekststreng med ein annan. Kan brukast til å byta ut både teikn og tal (tala vert automatisk gjorde om til tekst). Resultatet av denne funksjonen vert alltid vist som tekst. Om du vil gjera fleire utrekningar på eit tal som er bytt ut med tekst, må du gjera om teksten til eittal ved å bruka VERDI-funksjonen.

All tekst som inneheld tal må vera i hermeteikn (") dersom du ikkje ønskjer at han skal tolkast som tal og automatisk verta konvertert til tekst.

#### Syntaks

ERSTATT("Tekst"; Plassering; Lengd; "NyTekst")

Tekst er den teksten der ein del av innhaldet skal bytast ut.

Posisjon er startpunktet for utskiftinga.

Lengd er kor mange teikn i Tekst som skal bytast ut.

NyTekst er den teksten som skal bytast ut i Tekst.

#### Eksempel

ERSTATT("1234567"; 1; 1; "444") returnerer "444234567". Eitt teikn i posisjon 1 er erstatta av heile NyTekst.

## FAST (FIXED på engelsk)

Returnerer eit tal som tekst med eit bestemt tal på desimalar og valfrie tusenskiljeteikn.

#### Syntaks

FAST(Tal; [Desimalar = 2[; IngenTusenskiljeteikn = USANN]])

Tal vert avrunda til Desimal desimalplassar (etter desimalskiljeteiknet) og resultatet vert formatert som tekst, med lokale innstillingar.

Desimalar (valfri) er kor mange desimalar som skal visast. VissDesimalar er negativ, vert Tal avrunda til ABS (Desimalar) (absolutte desimalar) til venstre for desimalteiknet. Viss Desimalar er ein brøk, vert berre heile talet brukt.

IngenTusenskilje (valfri) bestemmer om det skal brukast tusenskiljeteikn. Viss denne er sett til Sann eller eit anna tal enn null, vert tusenskileteiknet ikkje brukt i resultatstrengen. Viss parameteren er lik 0 eller manglar heilt, vert tusentalsskiljeteikna frå den aktuelle lokale innstillinga brukt.

#### Eksempel

=FAST(1234567,89;3) returnerer 1.234.567,890 som ein tekststreng.

=FAST(123456,789;;Sann) returnerer 123456,79 som ein tekststreng.

=FAST(12345,6789;-2) returnerer 12,300 som ein tekststreng.

=FAST(1234567,89;-3;1) returnerer 12135000 som ein tekststreng.

=FAST(12345,789;3/4) returnerer 12.346 som ein tekststreng.

=FAST(12345,789;5/4) returnerer 12 345,8 som ein tekststreng.

## FINN (FIND på engelsk)

Returnerer plasseringa av ein streng i ein annan streng. Du kan òg skriva inn kvar søket skal byrja.Søkjeordet kan vera eit tal eller ein annan teiknstreng. Søket skil mellom store og små bokstavar.

#### Syntaks

FINN("FinnTekst"; "Tekst"[; Plassering])

FinnTekst er teksten som skal finnast. («Nåla»).

Tekst er teksten det skal søkjast i. («Høystakken»).

Plasering (valfri) er posisjonen i teksten som søket skal byrja frå.

#### Eksempel

=FINN(76; 998877665544) returnerer 6.

## GJENTA (REPT på engelsk)

Denne funksjonen tek opp att ein tekststreng eit visst tal gongar.

#### Syntaks

GJENTA("Tekst"; Tal)

Tekst er teksten som skal gjentakast.

Tal er talet på gjentakingar.

#### Eksempel

=GENTA("God morgon";2) returnerer God morgonGod morgon.

Sjå wikisida REPT for å sjå meir om denne funksjonen (på engelsk).

## HØGREB

Returnerer det siste teiknet eller dei siste teikna i ein tekst som brukar dobbelbyte teiknsett (DBCS).

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.

#### Syntaks

HØGREB("Tekst" [; Tal_byte])

Tekst er teksten som dei høgre teikna skal hentast ut frå.

Tal_på_byte (valfri) er talet på kor mange teikn HØGREB skal trekkja ut, basert på byte. Dersom denne parameteren ikkje er sett, vert eitt teikn returnert.

#### Eksempel

HØGREB("中国";1) returnerer « » (1 byte er berre halvparten av eit DBCS-teikn og mellomrom vert returnert i staden).

HØGREB("中国";2) returnerer «国» (2 byte er eit fullstendig DBCS-teikn).

HØGREB("中国";3) returnerer « 国» (3 byte er eitt og eit halvt DBCS-teikn. Det vert difor returnert eit mellomrom for det første halve teiknet).

HØGREB("中国";4) returnnerer «中国» (4 byte er to fullstendige DBCS-teikn).

HØGEB("office";3) returnerer «ice» (3 ikkje-DBCS-teikn, kvar på 1 byte).

## HØGRE (RIGHT på engelsk)

Returnerer teikna lengst til høgre i ein tekst.

#### Syntaks

HØGRE("Tekst" [; Tal])

Tekst er teksten som teikna skal hentast ut frå.

Tal (valfri) er talet på kor mange teikn frå byrjinga av teksten som skal returnerast. Dersom denne parameteren ikkje er sett, vert det returnert eitt teikn.

#### Eksempel

=HØGRE("Søndag";2) returnerer ag.

## KJEDA.SAMAN (CONCATENATE på engelsk)

Slår saman fleire deltekstar til ein samanhengande tekst.

#### Syntaks

KJEDA.SAMAN(Streng 1[; Streng 2][; … ;[Streng 255]])

Streng 1[; Streng 2][; … ;[Streng 255]] er strengar eller referansar til celler som inneheld strengar.

#### Eksempel

=KJEDA.SAMAN("God ";"morgon ";"fru ";"Nordmann") returnerer: God morgon fru Nordmann.

## KODE (CODE på engelsk)

Returnerer ein talkode for det første teiknet i ein tekststreng.

#### Syntaks

KODE("Tekst")

Tekst er teksten der koden til det første teiknet skal finnast.

Kodar som er større enn 127 er avhengige av kva for teiknsett du brukar på systemet ditt (for eksempel ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250) og det er difor ikkje sikkert at dei er portable.

#### Eksempel

=KODE("Hieronymus") returnerer 72, =KODE("hieroglyfisk") returnerer 104.

Koden som vert bruk her refererer ikkje til ASCII, men til den teikntabellen som er i bruk.

## LENGDB

For teiknsett som brukar to byte for å definera eit teikn (DBCS). Returnerer talet på byte som er brukte for å laga teikna i ein tekststreng.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.

#### Syntaks

LENGDB("Tekst")

Tekst er teksten som du skal finne lengda til.

#### Eksempel

LENGDB("中") returnerer 2 (1 DBCS-teikn inneheld 2 byte).

LENGDB("中国") returnerer 4 (2 DBCS-teikn med 2 byte kvar).

LENGDB("office") returnerer 6 (6 ikkje-DBCS-teikn der kvat teikn inneheld 1 byte).

=LENGDB("God ettermiddag") returnerer 15.

=LENGDB(12345,67) returnerer 8.

## LENGD (LEN på engelsk)

Returnerer lengda på ein tekststreng medrekna mellomrom.

#### Syntaks

LENGD("Tekst")

Tekst er teksten som du skal finne lengda til.

#### Eksempel

=LENGD("God ettermiddag") returnerer 15.

=LENGD(12345,67) returnerer 8.

## MIDB

Returnerer ein tekststreng frå ein DBCS-tekst. Parameterane gjev startposisjonen og kor mange teikn som skal returnerast.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.

#### Syntaks

MIDTB("Tekst"; Start; Tal_på_byte)

Tekst er teksten som teikna skal hentast frå.

Start er posisjonen for det første teiknet i strengen du skal hente ut.

Tal_på_byte er kor mange teikn MIDTB skal hente ut frå teksten, i byte.

#### Eksempel

MIDTB("中国";1;0) returnerer «» (0 byte er alltid ein tom streng).

MIDTB("中国";1;1) returnerer « » (1 byte er berre eit halvt DBCS-teikn og resultatet vert difor eit mellomrom).

MIDTB("中国";1;2) returnerer «中» (2 byte er eit fullstendig DBCS-teikn).

MIDTB("中国";1;3) returnerer «中 » (3 byte er eitt og eit halvt DBCS-teikn. Det siste teiknet er difor eit mellomrom).

MIDTB("中国";1;4) returnnerer «中国» (4 byte er to fullstendige DBCS-teikn).

MIDTB("中国";2;1) returnerer « » (den 2. byteposisjonen er ikkje i byrjinga av eit teikn i ein DBCS-streng og resultatet vert difor eit mellomrom).

MIDTB("中国";2;2) returnerer « » (den 2. byteposisjonen peikar til den siste halvdelen av det første teiknet i ein DBCS-streng. Dei 2 bytane som vert returnerte er difor den siste halvparten av det første teiknet og den første halvparten av det andre teiknet. Det vert difor returnert 2 mellomrom).

MIDTB("中国";2;3) returnerer « 国» (den 2. byteposisjonen er ikkje byrjinga av eit teikn i ein DBCS-streng og resultatet vert difor eit mellomrom for byteposisjon 2).

MIDTB("中国";3;1) returnerer « » (den 3. byteposisjonen er ved byrjinga av eit teikn i ein DBCS-streng, men 1 byte er berre halvparten av eit DBCS-teikn og difor vert det returnert eit mellomrom).

MIDTB("中国";3;2) returnerer «国» (den 3. byteposisjonen er ved byrjinga av eit teikn i ein DBCS-streng og 2 byte utgjer eit DBCS-teikn).

MIDTB("kontor";2;3) returnerer «ont» (den 2. byteposisjonen er ved byrjinga av eit teikn i ein ikkje-DBCSstreng og 3 byte av ein ikkje-DBCS-streng utgjer 3 teikn).

## MIDT

Returnerer ein tekststreng frå ein tekststreng. Parameterane gjev startposisjonen og kor mange teikn.

#### Syntaks

MIDT("Tekst"; Start; Tal)

Tekst er teksten som teikna skal hentast frå.

Start er posisjonen for det første teiknet i strengen du skal hente ut.

Tal er kor mange teikn som skal hentast ut.

#### Eksempel

=MIDT("office";2;2) returnerer ff.

## NØYAKTIG (EXACT på engelsk)

Samanliknar to tekststrengar og returnerer SANN om dei er nøyaktig like, elles USANN. Denne funksjonen skil mellom store og små bokstavar.

#### Syntaks

NØYAKTIG("Tekst1"; "Tekst2")

Tekst1 er den første teksten som skal samanliknast.

Tekst2 er den andre teksten som skal samanliknast.

#### Eksempel

=NØYAKTIG("microsystems"; "Microsystems") returnerer USANN.

## REINSK (CLEAN på engelsk)

Fjernar alle teikn som ikkje kan skrivast ut frå strengen.

#### Syntaks

REINSK("Tekst")

Tekst refererer til teksten som alle teikn som ikkje kan skrivast ut, vert fjerna frå.

#### Eksempel

=LENGD(REINSK(TEIKNKODE(7) & "LibreOffice Calc" & TEIKNKODE(8))) returnerer 16 og viser at funksjonen REINSK fjernar dei ikkje-utskrivbare teikna Unicode U+0007 ("BEL") og U+0008 ("BS") i byrjinga og slutten av strengen. REINSK fjernar ikkje mellomrom.

## SMÅ (LOWER på engelsk)

Gjer om alle store bokstavar i ein tekst til små bokstavar.

#### Syntaks

SMÅ("Tekst")

Tekst refererer til teksten som skal konverterast.

#### Eksempel

=SMÅ("Sola") returnerer sola.

## STORE (UPPER på engelsk)

Gjer om strengen i tekstfeltet til store bokstavar.

#### Syntaks

STORE("Tekst")

Tekst er teksten med små bokstavar som du vil konvertera til store bokstavar.

#### Eksempel

=STORE("God morgon") returnerer GOD MORGON.

## STOR.FORBOKSTAV (PROPER på engelsk)

Skriv den første bokstaven i kvart ord i ein tekststreng med stor forbokstav.

#### Syntaks

STOR.FORBOKSTAV("Tekst")

Tekst refererer til teksten som skal konverterast.

#### Eksempel

=STOR.FORBOKSTAV("dette er ein tekst") returnerer «Dette Er Ein Tekst».

## SØK (SEARCH på engelsk)

Returnerer posisjonen til ein deltekst i ein tekststreng. Du kan setja startposisjonen til søket. Søkjeteksten kan vera eit tal eller ein streng med teikn. Søket skil ikkje mellom store og små bokstavar. Viss teksten ikkje vart funnen, vert feilmeldinga 519 (#VERDI) vist.

Søkinga har støtte for jokerteikn eller regulære uttrykk. Med regulære uttrykk slått på, kan du for eksempel skriva inn «all.*» for å finna den første staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal søkja etter ein tekst som også er eit regulært uttrykk, må du anten skriva bakoverstrek (\) framføre kvar operator eller kvart metateikn eller du må lukka inn teksten mellom «\Q» og «\E». Du kan slå den automatiske evalueringa av jokerteikn og regulære uttrykk av eller på frå iLibreOffice → InnstillingarVerktøy → Innstillingar → LibreOffice Calc → Rekn ut.

Når du brukar funksjonar der eitt eller fleire argument er søkjekriterium som representerer eit regulært uttrykk, vert det først prøvd å konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og så vidare. Viss dette går bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. Når du brukar eit språk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulære uttrykk fungera. For å tvinga evalueringa av det regulære uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».

#### Syntaks

SØK("FinnTekst"; "Tekst"[; Plassering])

FinnTekst er teksten det skal søkast etter.

Tekst er teksten det skal søkast i.

Plassering (valfri) er plasseringa i teksten som søket skal byrje frå.

#### Eksempel

=SØK(54; 998877665544) returnerer 10.

## T

Denne funksjonen returnerer målteksten, eller ein tom tekststreng viss målet ikkje er ein tekst.

#### Syntaks

T(Verdi)

Dersom Verdi er ein tekststreng eller refererer til ein tekststreng, returnerer T denne tekststrengen, ellers returnerer han ein tom tekststreng.

#### Eksempel

=T(12345) returnerer ein tom streng "".

=T("12345") returnerer strengen 12345.

## TEIKNKODE

Gjer om eit tal til eit teikn i samsvar med den kodetabellen som er i bruk. Talet kan vera to- eller tresifra og berre heile tal kan brukast.

Kodar som er større enn 127 er avhengige av kva for teiknsett du brukar på systemet ditt (for eksempel ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250) og det er difor ikkje sikkert at dei er portable.

#### Syntaks

TEIKNKODE(Tal)

Tal er eit heiltal mellom 1 og 255 som representerer talverdien til teiknet.

#### Eksempel

TEIKNKODE(100) returnerer teiknet d.

="abc" & CHAR(10) & "def" set teiknet for linjeskift inn i strengen.

## TEKST (TEXT på engelsk)

Omformar ein verdi til tekst ut frå det gjevne formatet.

#### Syntaks

TEKST(Verdi; Format)

Verdi er den nummeriske verdien eller tekstverdien som skal omformast.

Format er teksten som definerer formatet. Bruk desimal- og tusenskiljeteikn ut frå språkinnstillinga i celleformatet.

#### Eksempel

=TEKST(12,34567;"###,##") returnerer teksten 12,35

=TEKST(12,34567;"000,00")returnerer teksten 012,35

=TEXT("xyz";"=== @ ===") returnerer teksten === xyz ===

Sjå også Talformatkodar: tilpassa formatkodar definert av brukaren.

## TRIM

Tar bort ekstra mellomrom frå ein streng slik at det berre vert igjen eitt mellomrom mellom ord.

#### Syntaks

TRIM("Tekst")

Tekst er teksten som mellomromma skal fjernast frå.

#### Eksempel

=TRIM(" hallo......verda ") returnerer «hallo verda» utan mellomrom før og etter, og eitt enkelt mellomrom mellom orda.

## UNICODE

Returnerer talkoden for det første Unicode-teiknet i ein tekststreng.

#### Syntaks

UNICODE("Tekst")

#### Eksempel

=UNICODE("©") returnerer unicodeverdien 169 for copyrightteiknet.

Sjå også UNITEIKN()-funksjonen.

## UNITEIKN (UNICHAR på engelsk)

Konverterer ein teiknkode til eit Unicode-teikn eller ein Unicode-bokstav.

#### Syntaks

UNITEIKN(tal)

#### Eksempel

=UNITEIKN(169) returnerer opphavsrett-teiknet ©.

Sjå også UNICODE()-funksjonen.

## VALUTA (DOLLAR på engelsk)

Konverterer eit tal til ein tekst summen i valutaformatet, avrunda til gjevne desimalplassar ved hjelp av desimalskiljeteiknet som svarar til gjeldande lokale innstillingar. Du skriv inn talet som skal konverterast i feltet Verdi. Du kan eventuelt skriva inn talet på desimalar i feltet Desimalar. Viss det ikkje er gjeve nokon verdi her, vert alle tal viste i valutaformat med to desimalar.

Du bestemmer valutaformatet i systeminnstillingane.

#### Syntaks

VALUTA(Verdi[; Desimalar})

Verdi er eit tal, ein referanse til ei celle med eit tal eller ein formel som returnerer eit tal.

Desimalar er talet på desimalar.

#### Eksempel

=VALUTA(255) returnerer $255.00 for den engelske lokaliseringa (USA) og valutaen USD (dollar); ￥255.00 for den japanske lokalisering og valutaen JPY (yen), 255,00 € for tysk lokalisering (Tyskland) og valutaen EUR (euro) eller kr 255,00 for norsk lokalisering.

=VALUTA(367,456;2) returnerer kr 367,46.

## VENSTREB

Returnerer dei første teikna av ein DBCS-tekst.

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.

#### Syntaks

VENSTREB("Tekst"[; Tal_på_byte])

Tekst er teksten teikna skal hentast frå.

Tal_på_byte (valfri) er talet på kor mange teikn frå byrjinga av teksten som skal returnerast, basert på byte. Dersom denne parameteren ikkje er sett, vert eitt teikn returnert.

#### Eksempel

VENSTREB("中国";1) returnerer « » (1 byte er berre halvparten av eit DBCS-teikn og mellomrom vert returnert i staden).

VENSTREB("中国";2) returnerer «中» (2 byte er eit fullstendig DBCS-teikn).

VENSTREB("中国";3) returnerer «中 » (3 byte er eitt og eit halvt DBCS-teikn. Det siste teiknet er difor eit mellomrom).

VENSTREB("中国";4) returnnerer «中国» (4 byte er to fullstendige DBCS-teikn).

VENSTREB("kontor";3) returnerer "kon" (3 ikkje-DBCS-teikn, kvar på 1 byte).

## VENSTRE (LEFT på engelsk)

Returnerer det første teiknet eller dei første teikna i ein tekst.

#### Syntaks

VENSTRE("Tekst"[; Tal])

Tekst er teksten teikna skal hentast frå.

Tal (valfri) er talet på kor mange teikn frå byrjinga av teksten som skal returnerast. Dersom denne parameteren ikkje er sett, vert det returnert eitt teikn.

#### Eksempel

=VENSTRE("utdata"; 3) returnerer «utd».

Liknande emne

Funksjonar etter kategori