Innhold
Innholdsliste 🔎︎

# Databasefunksjoner

### Oversikt

De tolv funksjonene i Database-kategorien hjelper deg med å analysere en enkel database som opptar et rektangulært regnearkområde som består av kolonner og rader, med dataene organisert som én rad for hver post. Overskriften celle i hver kolonne viser navnet på kolonnen, og det navnet gjenspeiler vanligvis innholdet i hver celle i den kolonnen.

Funksjonene i kategorien Database har tre argumenter som følger:

1. Database. Celleområdet til databasen.

2. Databasefelt. Kolonnen som inneholder dataene som skal brukes i funksjonens beregninger.

3. Søkekriterier. Celleområdet til et eget område av regnearket som inneholder søkekriterier.

Disse argumentene er beskrevet mer fullstendig nedenfor.

Alle funksjoner har samme driftskonsept. Det første logiske trinnet er å bruke de spesifiserte Søkekriteriene for å identifisere undersettet av poster i Databasen som skal brukes under påfølgende beregninger. Det andre trinnet er å trekke ut dataverdiene og utføre beregningene knyttet til den spesifikke funksjonen (gjennomsnitt, sum, produkt og så videre). Verdiene som behandles er de i Database Felt-kolonnen i de valgte postene.

Calc behandler datoer og logiske verdier (SANN og USANN) som numeriske ved beregning med disse funksjonene.

### Databasefunksjonsargumenter

Følgende argumentdefinisjoner gjelder for alle funksjoner i databasekategorien:

1. Database argumenter

   Database spesifiserer celleområdet som er okkupert av databasetabellen. Den første raden i området inneholder feltnavnene, og påfølgende rader er poster med tilsvarende feltverdier.

   En måte å definere celleområdet på er å angi cellereferansen for den øvre venstre cellen, etterfulgt av et kolon (:), og deretter den nedre høyre cellereferansen. Et eksempel kan være A1:E10.

   Argumentet Database kan også spesifiseres ved å sende navnet på et navngitt område eller databaseområde. Å bruke et meningsfylt navn for å definere celleområdet kan forbedre formellesbarheten og dokumentvedlikeholdet. Hvis navnet ikke samsvarer med navnet på et definert område, rapporterer Calc et #NAME? feil.

   Andre feil som kan rapporteres som et resultat av et ugyldig Database-argument er #VALUE! og Err:504 (feil i parameterlisten).

2. Databasefelt argument

   DatabaseField spesifiserer kolonnen som funksjonen vil bruke for sine beregninger etter at søkekriteriene er brukt og dataradene er valgt. Det er ikke relatert til søkekriteriene.

   Spesifiser DatabaseFelt-argumentet på en av følgende måter:

   - Ved å skrive inn en referanse til en overskriftscelle i Database-området. Alternativt, hvis cellen har fått et meningsfylt navn som et navngitt område eller databaseområde, skriv inn det navnet. Hvis navnet ikke samsvarer med navnet på et definert område, rapporterer Calc et #NAME? feil. Hvis navnet er gyldig, men ikke bare tilsvarer én celle, rapporterer Calc Err:504 (feil i parameterlisten).

   - Ved å angi et tall for å spesifisere kolonnen innenfor Database-området, som starter med 1. For eksempel, hvis en Database okkuperte celleområdet D6:H123, skriv inn 3 for å indikere overskriftscellen ved F6. Calc forventer en heltallsverdi som ligger mellom 1 og antall kolonner definert i Database og ignorerer alle sifre etter et desimaltegn. Hvis verdien er mindre enn 1, rapporterer Calc Err:504 (feil i parameterlisten). Hvis verdien er større enn antall kolonner i Database, rapporterer Calc en #VERDI! feil.

   - Ved å skrive inn det bokstavelige kolonneoverskriftsnavnet fra den første raden i Database-området, plasserer du anførselstegn rundt overskriftsnavnet. For eksempel "Avstand til skolen". Hvis strengen ikke samsvarer med en av Database-områdets kolonneoverskrifter, rapporterer Calc Err:504 (feil i parameterlisten). Du kan også gi en referanse til en vilkårlig celle (ikke innenfor Database- og Søkekriterier-områdene) som inneholder den nødvendige strengen.

   Argumentet DatabaseFelt er valgfritt for funksjonene DCOUNT og DCOUNTA, men det kreves for de ti andre databasefunksjonene.

3. Argument for søkekriterier

   Søkekriterier spesifiserer celleområdet som inneholder søkekriterier. I likhet med Database er dens første rad også feltnavn, og påfølgende rader er betingelser for relaterte felt. Områdene Database og Søkekriterier trenger ikke være tilstøtende, eller til og med på samme ark.

   En måte å definere celleområdet på er å angi cellereferansen for den øvre venstre cellen, etterfulgt av et kolon (:), og deretter den nedre høyre cellereferansen. For eksempel A13:B14. Celleområdet kan også spesifiseres ved å sende navnet på et definert navngitt område eller databaseområde. Hvis navnet ikke samsvarer med navnet på et definert område, rapporterer Calc et #NAME? feil.

   Err:504 (feil i parameterlisten) kan også rapporteres som et resultat av et ugyldig Søkekriterie-argument.

   Innholdet i Søkekriterier-området er beskrevet mer detaljert i neste avsnitt.

### Definere søkekriterier

Antallet kolonner som er brukt av Søkekriterier-området trenger ikke være det samme som bredden på Database-området. Alle overskrifter som vises i den første raden i Søkekriterier må være identiske med overskriftene i den første raden i Database. Imidlertid trenger ikke alle overskrifter i Database vises i den første raden i Søkekriterier, mens en overskrift i Database kan vises flere ganger i den første raden av Søkekriterier.

Søkekriterier legges inn i cellene i den andre og påfølgende raden i Søkekriterier-området, under raden som inneholder overskrifter. Tomme celler i Søkekriterier-området ignoreres.

Lag kriterier i cellene i Søkekriterier-området ved å bruke sammenligningsoperatorene <, <=, =, <>, >= og >. = antas hvis en celle ikke er tom, men ikke starter med en sammenligningsoperator.

Hvis du skriver flere kriterier på en rad, er de koblet sammen med OG. Hvis du skriver flere kriterier i forskjellige rader, er de forbundet med OR.

Kriterier kan opprettes ved hjelp av jokertegn, forutsatt at jokertegn er aktivert via Aktiver jokertegn i formler-alternativet på LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn dialog. Når interoperabilitet med Microsoft Excel er viktig for regnearket ditt, bør dette alternativet være aktivert.

Enda kraftigere kriterier kan opprettes ved bruk av regulære uttrykk, forutsatt at regulære uttrykk er aktivert via Aktiver regulære uttrykk i formler-alternativet på LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn dialog.en

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

En annen innstilling som påvirker hvordan søkekriteriene håndteres er Søkekriterier = og <> må gjelde for hele celler alternativet på LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn dialog. Dette alternativet kontrollerer om søkekriteriene du angir for databasefunksjonene må samsvare nøyaktig med hele cellen. Når interoperabilitet med Microsoft Excel er viktig for regnearket ditt, bør dette alternativet være aktivert.

### Eksempler på bruk av databasefunksjoner

Tabellen nedenfor gir et eksempel på en databasetabell som brukes til å demonstrere hvordan du bruker funksjonene i kategorien Database. Celleområdet A1:E10 inneholder fiktiv informasjon om gjestene som er invitert til Joes bursdagsfest. Følgende informasjon er gitt for hver gjest - navn, skolekarakter, alder i år, avstand til skolen i meter og vekt i kilo.

| A | B | C | D | E
1 | Navn | Karakter | Alder | Avstand | Vekt
2 | Andy | 3 | 9 | 150 | 40
3 | Betty | 4 | 10 | 1000 | 42
4 | Charles | 3 | 10 | 300 | 51
5 | Daniel | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Frank | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Harry | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |

De følgende seks eksemplene bruker databasetabellen ovenfor, kombinert med ulike søkekriterieområder.

#### Eksempel 1

| A | B | C | D | E
12 | Navn | Karakter | Alder | Avstand | Vekt
13 |  |  |  | >600 |
14 |  |  |  |  |

Som i dette enkle eksemplet, er det noen ganger ønskelig (men ikke avgjørende) å plassere søkekriterieområdet direkte under databasetabellen, med kolonnene til de to områdene vertikalt justert. Tomme oppføringer i søkekriterieområdet ignoreres. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;A12:E14) i en tom celle et annet sted i arket for å telle hvordan mange av Joes gjester reiser lenger enn 600 meter til skolen. Verdien 5 returneres (teller Betty, Daniel, Eva, Harry og Irene).

Merk også at formelen =DCOUNT(A1:E10;;D12:D13) returnerer nøyaktig samme verdi, noe som viser at det bare er nødvendig at søkekriterieområdet inneholder relevant kolonne overskrifter.

#### Eksempel 2

| A | B | C | D | E
12 |  | Alder | Karakter |  |
13 |  | >7 | 2 |  |
14 |  |  |  |  |

I dette eksemplet inneholder søkekriterieområdet bare to overskrifter, og disse er ikke vertikalt justert med de tilsvarende overskriftene i eksempeldatabasetabellen. Siden det er to forhold i samme rad, er disse forbundet med OG. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;B12:C13) i en tom celle et annet sted i arket for å telle hvordan mange av gjestene til Joe er i klasse 2 og eldre enn 7 år. Verdien 2 returneres (teller Eva og Irene).

#### Eksempel 3

| A | B | C | D | E
12 |  | Alder |  |  |
13 |  | 9 |  |  |
14 |  | 10 |  |  |

I dette eksemplet inneholder søkekriterieområdet kun én overskrift. Siden det er to forhold i påfølgende rader, er disse forbundet med ELLER. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;B12:B14) i en tom celle et annet sted i arket for å telle hvordan mange av Joes gjester er enten 9 eller 10 år gamle. Verdien 4 returneres (teller Andy, Betty, Charles og Harry).

#### Eksempel 4

| A | B | C | D | E
12 |  | Alder | Alder |  |
13 |  | >=8 | <=10 |  |
14 |  |  |  |  |

I dette eksemplet inneholder søkekriterieområdet to forekomster av samme overskrift. Siden det er to forhold i samme rad, er disse forbundet med OG. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;B12:C13) i en tom celle et annet sted i arket for å telle hvordan mange av Joes gjester er mellom 8 og 10 år (inkludert). Verdien 6 returneres (teller Andy, Betty, Charles, Eva, Harry og Irene).

#### Eksempel 5

| A | B | C | D | E
12 | Navn |  |  |  |
13 | F* |  |  |  |
14 |  |  |  |  |

Dette enkle eksemplet viser bruken av jokertegn. For at dette eksemplet skal fungere etter hensikten, velg å aktivere jokertegn på LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;A12:A13) i en tom celle et annet sted i arket for å telle hvordan mange av Joes gjester har navn som begynner med bokstaven "F". Verdien 1 returneres (teller Frank).

#### Eksempel 6

| A | B | C | D | E
12 | Navn |  |  |  |
13 | [ABC].* |  |  |  |
14 |  |  |  |  |

Dette enkle eksemplet viser bruken av regulære uttrykk. For at dette eksemplet skal fungere etter hensikten, velg å aktivere regulære uttrykk på LibreOffice - InnstillingerVerktøy - Alternativer - LibreOffice Calc - Beregn. Med eksempeldatabasetabellen ovenfor og dette søkekriterieområdet setter du inn formelen =DCOUNT(A1:E10;;A12:A13) i en tom celle et annet sted i arket for å telle hvordan mange av Joes gjester har navn som begynner med bokstavene "A", "B" eller "C". Verdien 3 returneres (teller Andy, Betty og Charles).

## DANTALLA (DCOUNTA på engelsk)

DCOUNTA teller antall celler (felt) i den angitte kolonnen som ikke er tomme, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Tomme celler i den angitte kolonnen regnes ikke. Men hvis ingen kolonne er spesifisert, returnerer DCOUNTA antallet av alle poster som samsvarer med de angitte søkekriteriene uavhengig av innholdet.

#### Syntaks

DCOUNT(Database; [DatabaseField]; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">600" (dette søkekriteriet vil samsvare med poster i databasetabellen som har en verdi større enn 600 i Avstand-kolonnen).

Sett inn formelen =DCOUNTA(A1:E10;; A12:E13) i en tom celle et annet sted i arket for å beregne hvor mange av Joes festgjester som reiser lenger enn 600 meter til skolen. Verdien 5 returneres.

Det samme resultatet oppnås hvis du bruker formelen =DCOUNTA(A1:E10; "Avstand"; A12:E13) eller formelen =DCOUNTA(A1:E10; "Navn"; A12 :E13). Det siste tilfellet gjenspeiler at i motsetning til DCOUNT, teller DCOUNTA både numeriske og alfanumeriske verdier i kolonnen som er angitt av DatabaseField-argumentet.

## DANTALL (DCOUNT på engelsk)

DCOUNT teller antall celler (felt) i den angitte kolonnen som inneholder numeriske verdier, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Men hvis ingen kolonne er spesifisert, returnerer DCOUNT antallet av alle poster som samsvarer med de angitte søkekriteriene, uavhengig av innholdet.

#### Syntaks

DCOUNT(Database; [Databasefelt]; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">600" (dette søkekriteriet vil samsvare med poster i databasetabellen som har en verdi større enn 600 i Avstand-kolonnen).

Sett inn formelen =DCOUNT(A1:E10;; A12:E13) i en tom celle et annet sted i arket for å beregne hvor mange av Joes festdeltagere som reiser lenger enn 600 meter til skolen. Verdien 5 returneres.

Det samme resultatet oppnås hvis du bruker formelen =DCOUNT(A1:E10; "Avstand"; A12:E13), fordi alle oppføringer i Avstand-kolonnen er numeriske. Men hvis du bruker formelen =DCOUNT(A1:E10; "Navn"; A12:E13), returneres verdien 0 fordi alle oppføringer i Navn-kolonnen er ikke-numeriske.

## DHENT

DGET returnerer innholdet i cellen (feltet) i den spesifiserte kolonnen, for enkeltraden (databaseposten) som samsvarer med de angitte søkekriteriene.

Calc rapporterer Err:502 (ugyldig argument) hvis flere treff blir funnet, eller en #VALUE! feil (feil datatype) hvis ingen treff blir funnet. EN VERDI! feil rapporteres også hvis en enkelt match blir funnet, men den relevante cellen er tom.

#### Syntaks

DHENT(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:E13 er tomme, bortsett fra celle C13 som skal inneholde "11" (dette søkekriteriet vil samsvare med poster i databasetabellen som har en verdi på 11 i Alder-kolonnen).

Sett inn formelen =DGET(A1:E10; "Navn"; A12:E13) i en tom celle et annet sted i arket for å finne navnet på Joes festdeltager som er 11 år. Navnet Daniel er returnert.

Hvis du endrer verdien i celle C13 til "10", returnerer formelen =DGET(A1:E10; "Navn"; A12:E13) en ugyldig argumentfeil (Err:502). Det gjenspeiler at flere poster samsvarer med det spesifiserte kriteriet (både Betty og Charles er 10 år).

## DMAKS

DMAX beregner maksimumsverdien på tvers av cellene (feltene) i den angitte kolonnen som inneholder numeriske verdier, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Tomme celler eller celler som inneholder ikke-numeriske tegn er ikke inkludert.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier som ikke er null i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DMAKS(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DMAX(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å finne den maksimale avstanden i meter som noen av Joes festgjester reiser til skolen. Verdien 1200 returneres.

## DMIDDEL

DAVERAGE beregner gjennomsnittet av de numeriske verdiene i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Ikke-numeriske verdier i disse cellene blir ignorert.

Returnerer en #DIV/0! feil hvis ingen poster samsvarer med de angitte søkekriteriene, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DMIDDEL(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DAVERAGE(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å beregne den gjennomsnittlige avstanden i meter reist til skolen av Joes festgjester. Verdien 666,67 returneres.

## DMIN

DMIN beregner minimumsverdien på tvers av cellene (feltene) i den angitte kolonnen som inneholder numeriske verdier, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Tomme celler eller celler som inneholder ikke-numeriske tegn er ikke inkludert.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier som ikke er null i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DMIN(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DMIN(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å finne minimumsavstanden i meter som noen av Joes festgjester reiser til skolen. Verdien 150 returneres.

## DPRODUKT

DPRODUCT beregner produktet av alle numeriske verdier i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Tomme celler eller celler som inneholder ikke-numeriske tegn er ikke inkludert.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DPRODUKT(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:E13 er tomme, bortsett fra celle C13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DPRODUCT(A1:E10; "Alder"; A12:E13) i en tom celle et annet sted i arket for å beregne produktet av alderen i årene for Joes festdeltagere. Verdien 279417600 returneres.

## DSTDAV

DSTDEV beregner prøvestandardavviket basert på de numeriske verdiene i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Ikke- numeriske verdier ignoreres.

Returnerer et #NUM! feil hvis nøyaktig én post samsvarer med de angitte søkekriteriene, eller hvis det bare er én numerisk verdi i cellene i den angitte kolonnen for de samsvarende postene.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DSTDAV(Database; Databasefelt; Søkekriterier)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:D13 er tomme og at celle E13 inneholder ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DSTDEV(A1:E10; "Weight"; A12:E13) i en tom celle et annet sted i arket for å beregne prøvestandardavviket til vektene i kg for Joes festdeltagere. Verdien 5,5 returneres.

## DSTDAVP

DSTDEVP beregner populasjonsstandardavviket basert på de numeriske verdiene i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Ikke- numeriske verdier ignoreres.

Returnerer et #NUM! feil hvis ingen poster samsvarer med de angitte søkekriteriene, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DSTDAVP(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Sørg for at cellene A13:D13 er tomme og at celle E13 inneholder ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DSTDEVP(A1:E10; "Weight"; A12:E13) i en tom celle et annet sted i arket for å beregne populasjonsstandardavviket til vektene i kg for Joes festdeltagere. Verdien 5,18545 returneres.

## DSUM

DSUM beregner summen av alle numeriske verdier i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Tomme celler eller celler som inneholder ikke-numeriske tegn er ikke inkludert.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DSUM(Database; Databasefelt; Søkekriterier)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DSUM(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å finne den totale avstanden i meter som alle Joes festdeltagere reiser til skolen. Verdien 6000 returneres.

## DVARIANS

DVAR beregner prøvevariansen basert på de numeriske verdiene i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Ikke-numerisk verdier ignoreres.

Returnerer et #NUM! feil hvis nøyaktig én post samsvarer med de angitte søkekriteriene, eller hvis det bare er én numerisk verdi i cellene i den angitte kolonnen for de samsvarende postene.

Returnerer 0 hvis ingen treff blir funnet, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DVARIANS(Database; Databasefelt; Søkekriterium)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DVAR(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å finne prøvevariasjonen av avstandene i meter som Joes festdeltagere reiser til skolen . Verdien 193125 returneres.

## DVARIANSP

DVARP beregner populasjonsvariasjonen basert på de numeriske verdiene i cellene (feltene) i den angitte kolonnen, for alle rader (databaseposter) som samsvarer med de angitte søkekriteriene. Ikke-numerisk verdier ignoreres.

Returnerer et #NUM! feil hvis ingen poster samsvarer med de angitte søkekriteriene, eller hvis det ikke er noen numeriske verdier i cellene i den angitte kolonnen for de samsvarende postene.

#### Syntaks

DVARIANSP(Database; Databasefelt; Søkekriterier)

#### Eksempel

Eksempeldatabasetabellen som gir informasjon om gjestene som er invitert til Joes bursdagsfest (beskrevet ovenfor) bør oppta cellene A1:E10. Innholdet i cellene A12:E12 skal være identisk med overskriftsetikettene for databasetabellen i cellene A1:E1. Pass på at cellene A13:E13 er tomme, bortsett fra celle D13 som skal inneholde ">0" (dette søkekriteriet er ment å matche alle poster i databasetabellen).

Sett inn formelen =DVARP(A1:E10; "Avstand"; A12:E13) i en tom celle et annet sted i arket for å finne populasjonsvariasjonen av avstandene i meter som Joes festdeltagere reiser til skolen . Verdien 171666,67 returneres.

Lignende emner

Funksjoner etter kategori