Indhold
Indholdsfortegnelse 🔎︎

# AGGREGER-funktion

Denne funktion returnerer et aggregeret resultat af beregningen i området. Du kan benytte forskellige aggregeringsfunktioner som oplistet herunder. Aggreger-funktionen giver dig mulighed for at udelade skjulte rækker, fejl, subtotaler og andre AGGREGER-funktioner i beregningen.

AGGREGER-funktionen bruges på lodrette områder af data med aktiveret AutoFilter. Hvis AutoFilter ikke er aktiveret vil automatisk genberegning af funktionen ikke virke for nyligt skjulte rækker. Det er ikke meningen at funktionen skal virke på vandrette områder, men kan godt bruges, dog med visse begrænsninger. Specielt vil AGGREGER-funktionen tilknyttet et vandret område ikke respektere at skjule kolonner, men undgår korrekt fejl og resultater af SUBTOTAL og andre AGGREGER-funktioner inde i rækken.

### Syntaks

AGGREGER(Funktion; Indstillinger; Reference 1[; Reference 2][; ... ;[Reference 253]])

eller

AGGREGER( Funktion; Indstillinger; Matrix[; k])

Funktion – obligatorisk argument. Et funktionsindeks eller en reference til en celle med værdi fra 1 til 19, jf. følgende tabel.

Funktionsindeks | Benyttet funktion
--- | ---
1 | MIDDEL
2 | TÆL
3 | TÆLV
4 | MAKS
5 | MIN
6 | PRODUKT (PRODUCT på engelsk)
7 | STDAFV.S
8 | STDAFV.P
9 | SUM
10 | VARIANS.S
11 | VARIANS.P
12 | MEDIAN
13 | HYPPIGST.ENKELT
14 | STØRSTE (LARGE på engelsk)
15 | MINDSTE (SMALL på engelsk)
16 | FRAKTIL.MEDTAG
17 | KVARTIL.MEDTAG
18 | FRAKTIL.UDELAD
19 | KVARTIL.UDELAD

Valg – obligatorisk argument. Et valgindeks eller reference til en celle med værdi fra 0 til 7 afgør hvad der skal ignoreres i funktionen.

Valg-indeks | Tilknyttet valg
--- | ---
0 | Ignorer kun indlejrede SUBTOTAL og AGGREGER-funktioner
1 | Ignorer kun skjulte rækker, indlejrede SUBTOTAL og AGGREGER-funktioner
2 | Ignorer kun fejl samt indlejrede SUBTOTAL og AGGREGER-funktioner
3 | Ignorer skjulte rækker, fejl samt indlejrede SUBTOTAL og AGGREGER-funktioner
4 | Ignorer intet
5 | Ignorer kun skjulte rækker
6 | Ignorer kun fejl
7 | Ignorer kun skjulte rækker og fejl

Tal1 – påkrævet argument. Det første numeriske argument (hvis området er sat af en liste over værdier i funktionen) eller som en reference til den celle, som indeholder den.

Tal 2, 3, ... – valgfri. Et numerisk argument eller en reference til en celle (op til 253 argumenter), hvis aggregerede værdi, du har brug for.

matrix – påkrævet argument. Matrixen kan angives af områdets grænser, navnet på et navngivet område eller kolonneoverskriften.

For at bruge kolonneetiketten skal funktionen "Automatisk find kolonne- og rækkeetiketter" være aktiveret.

k – obligatorisk argument i de følgende funktioner: STØRSTE, MINDSTE, FRAKTIL.MEDTAG, KVARTIL.MEDTAG, FRAKTIL.UDELAD, KVARTIL.UDELAD. Det er et numerisk argument, som skal svare til det andet argument i disse funktioner.

### Eksempler

| A | B | C
1 | KolonneEt | KolonneTo | KolonneTre
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VÆRDI! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Returns maximum value for the range A2:A9 = 34.

=AGGREGER(9;5;A5:C5)
Returnerer summen for området A5:C5 = 29, selv om nogle af kolonnerne er skjulte.

=AGGREGER(9;5;B2:B9)
Returner summen af kolonnen B = 115. Hvis nogen række er skjult vil funktionen se bort fra dens værdi, for eksempel hvis den syvende række er skjult, vil funktionen returnere 95.

Hvis du behøver at anvende funktionen med et 3D-område, viser dette eksempel, hvordan det gøres.

=AGGREGER(13;3;Ark1.B2:B9:Ark3.B2:B9)
Funktionen returnerer tilstand af værdierne af anden kolonne, fra arkene 1:3 (der har de samme data) = 8.

Du kan referere til en celle eller et område for hvert enkelt argument i formlen. Følgende eksempel viser hvordan. Desuden viser eksemplet at du kan bruge kolonneetiketter til at definere arealet.

=AGGREGER(E3;E5;'ColumnOne')
Hvis E3 = 13 og E5 = 5, så returnener funktionen tilstanden af den første kolonne = 10.

#### Tekniske oplysninger

Denne funktion er tilgængelig siden LibreOffice 4.4.

Denne funktion er ikke en del af standarden Open Document Format for kontorprogrammer (OpenDocument) Version 1.3. del 4: Omregnet formel (OpenFormula) -format. Navnerummet er

COM.MICROSOFT.AGGREGATE

Relaterede emner

AGGREGATE wiki page.

MIDDEL, TÆL, TÆLV, MAKS, MIN, PRODUKT, STDAFV.S, STDAFV.P, SUM, VARIANS.S, VARIANS.P, MEDIAN, HYPPIGST.ENKELT, STØRSTE, MINDSTE, FRAKTIL.MEDTAG , KVARTIL.MEDTAG, FRAKTIL.UDELAD, KVARTIL.UDELAD

Find kolonne og række etiketter automatisk