Sumário

# Funções financeiras - Parte 2

Para acessar este comando...

Inserir - Função - Categoria Financeiro

Voltar às funções financeiras - Parte 1

Avançar para Funções Financeiras: Parte 3

## DPD

Retorna a depreciação linear de um ativo para um período. A quantia da depreciação é constante no período de depreciação.

#### Sintaxe

DPD(Custo; ValorResidual; Vida)

Custo é o custo inicial de um ativo.

ValorResidual é o valor de um ativo no final da depreciação.

Vida é o período de depreciação, que determina o número de períodos na depreciação do ativo.

#### Exemplo

Equipamentos de escritório com um custo inicial de 50.000 unidades monetárias devem ser depreciados em um período de 7 anos. O valor no final da depreciação será de 3.500 unidades monetárias.

=DPD(50000;3,500;84) = 553,57 unidades monetárias. A depreciação periódica mensal do equipamento de escritório é 553,57 unidades monetárias.

## IPGTO.CUM

Calcula os pagamentos de juros cumulativos, isto é, os juros totais para um investimento baseado em uma taxa de juros constante.

#### Sintaxe

IPGTO.CUM(Taxa; NPer; Pmt; VP; S; E; Tipo)

Taxa é a taxa de juros periódica.

NPer é o período de pagamento com o número total de períodos. NPER também pode ser um número fracionário.

PV é o valor atual na sequência de pagamentos.

S é o primeiro período.

E é o último período.

Tipo é a data de vencimento do pagamento no início ou no fim de cada período.

#### Exemplo

Quais são os pagamentos de juros a uma taxa de juros anual de 5,5%, um período de pagamento de pagamentos mensais por 2 anos e um valor à vista atual de 5.000 unidades monetárias? O período inicial será o 4º e o período final será o 6º. O pagamento será durante o início de cada período.

=IPGTO.CUM(5.5%/12;24;5000;4;6;1) = -57,54 unidades monetárias. Os pagamentos de juros para o período entre o 4o. e 6o. períodos é 57,54 unidades monetárias.

## IPGTO.CUM_ADD

Calcula os juros acumulados para um período.

As funções cujo nome terminem com _ADD ou _EXCEL2003 retornam os mesmos resultados que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

#### Sintaxe

IPGTO.CUM(Taxa; NPer; Pmt; VP; InícioPeríodo; FimPeríodo; Tipo)

Taxa define a taxa de juros de cada período.

NPer é o número total de períodos de pagamento. A taxa e NPER devem se referir à mesma unidade, e portanto ambas serão calculadas anualmente ou mensalmente.

VP é o valor presente.

InícioPeríodo é o primeiro pagamento para o cálculo.

FimPeríodo é o último período de pagamento para o cálculo.

Tipo é a data de vencimento do pagamento no fim de cada período (Tipo = 0) ou no início do período (Tipo = 1).

#### Exemplo

Foi feito o seguinte empréstimo hipotecário para um casa:

Taxa: 9,00 por cento ao ano (9% / 12 = 0,0075), Duração: 30 anos (NPER = 30 * 12 = 360), VP: 125.000 unidades monetárias.

Quanto de juros você deve pagar no segundo ano da hipoteca (nos períodos de 13 a 24)?

=IPGTO.CUM_ADD(0,0075;360;125000;13;24;0) retorna -11135,23.

Quanto de juros você deve pagar no primeiro mês?

=IPGTO.CUM_ADD(0,0075;360;125000;1;1;0) retorna -937,50.

## LUCRO

Calcula o lucro de um título.

#### Sintaxe

LUCRO(Liquidação; Vencimento; Taxa; Preço; Resgate; Frequência [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Taxa é a taxa de juros anual.

Preço é o preço (preço de aquisição) do título por 100 unidades monetárias do valor nominal.

Resgate é o valor de resgate do título por 100 unidades monetárias do valor nominal.

Frequência é o número de pagamentos de juros por ano. (1, 2 ou 4).

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é comprado em 15-02-1999. Ele vence em 15-11-2007. A taxa de juros é de 5,75%. O preço é de 95,04287 unidades monetárias por 100 unidades de valor nominal, o valor residual é de 100 unidades. Os juros são pagos duas vezes ao ano (frequência = 2) e a base é 0. De quanto será o lucro?

=LUCRO("1999-02-15"; "2007-11-15"; 0,0575; 95,04287; 100; 2; 0) retorna 0,065 ou 6,50 por cento.

## LUCRODESC

Calcula o lucro anual de um título sem juros.

#### Sintaxe

LUCRODESC(Liquidação; Vencimento; Preço; Resgate [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Preço é o preço (preço de aquisição) do título por 100 unidades monetárias do valor nominal.

Resgate é o valor de resgate do título por 100 unidades monetárias do valor nominal.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título sem juros é comprado em 15-02-1999. Ele vence em 01-03-1999. O preço é de 99,795 unidades monetárias por 100 unidades de valor nominal, o valor de resgate é de 100 unidades. A base é 2. De quanto é o lucro?

=LUCRODESC("1999-02-15"; "1999-03-01"; 99,795; 100; 2) retorna 0.052823 or 5,2823 por cento.

## LUCROVENC

Calcula o lucro anual de um título, do qual os juros são pagos na data de vencimento.

#### Sintaxe

LUCROVENC(Liquidação; Vencimento; Emissão; Taxa; Preço [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Emissão é a data de emissão do título.

Taxa é a taxa de juros do título na data de emissão.

Preço é o preço (preço de aquisição) do título por 100 unidades monetárias do valor nominal.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é comprado em 15-03-1999. Ele vence em 03-11-1999. A data de emissão foi 08-11-1998. A taxa de juros é de 6,25%, o preço é de 100,0123 unidades. A base é 0. De quanto será o lucro?

=LUCROVENC("1999-03-15"; "1999-11-03"; "1998-11-08"; 0,0625; 100,0123; 0) retorna 0,060954 ou 6,0954 por cento.

## MDURAÇÃO

Calcula a duração modificada de Macauley de um título com juros fixos, em anos.

#### Sintaxe

MDURAÇÃO(Liquidação; Vencimento; Cupom; Lucro; Frequência [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Cupom é a taxa de juros nominal anual (taxa de juros do cupom)

Lucro é o lucro anual do título.

Frequência é o número de pagamentos de juros por ano. (1, 2 ou 4).

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é comprado em 01-01-2001; a data de vencimento é 01-01-2006. A taxa nominal de juros é de 8%. O lucro é de 9,0%. Os juros são pagos duas vezes ao ano (a frequência é 2). Utilizando um cálculo de balanço de juros diário (base 3), qual é a extensão da duração modificada?

=DURACAOM("2001-01-01"; "2006-01-01"; 0,08; 0,09; 2; 3) retorna 4,02 anos.

## MOEDADEC

Converte uma cotação que foi dada como uma fração decimal para um número decimal.

#### Sintaxe

MOEDADEC(MoedaFracionaria; Fração)

MoedaFracionária é um número dado como fração decimal.

Fração é um número inteiro que será usado como denominador de uma fração decimal.

#### Exemplo

=MOEDADEC(1,02;16) representa 1 e 2/16 avos. Retorna 1,125.

=MOEDADEC(1,1;8) representa 1 e 1/8. Retorna 1,125.

## MOEDAFRA

Converte uma cotação que foi dada como um número decimal em uma fração decimal mista.

#### Sintaxe

MOEDAFRA(MoedaDecimal; Fração)

MoedaDecimal é um número decimal.

Fração é um número inteiro que será usado como denominador de uma fração decimal.

#### Exemplo

=MOEDAFRA(1,125;16) converte em frações de 16. O resultado é 1,02 para 1 mais 2/16.

=MOEDAFRA(1,125;8) converte em oitavos. O resultado é 1,1 para 1 mais 1/8.

## MTIR

Calcula a taxa interna de retorno modificada de uma série de investimentos.

#### Sintaxe

MTIR(Valores; Investimento; TaxaDeReInvestimento)

Valores corresponde à matriz ou a referência de célula para células cujo conteúdo corresponde aos pagamentos.

Investimento é a taxa de juros do investimento (os valores negativos da matriz)

TaxaDeReInvestimento:a taxa de juros do reinvestimento (os valores positivos da matriz)

#### Exemplo

Assumindo que o conteúdo das células é A1 = -5, A2 = 10, A3 = 15, e A4 = 8, e um valor de investimento de 0,5 e um valor de reinvestimento de 0,1, o resultado é 94,16%.

## NOMINAL

Calcula a taxa de juros nominal anual, dada a taxa efetiva e o número de períodos compostos por ano.

#### Sintaxe

NOMINAL(TaxaEfetiva; NPerA)

TaxaEfetiva é a taxa de juros efetiva

NPerA é o número de pagamentos periódicos de juros por ano.

#### Exemplo

Qual será o juro nominal por ano para uma taxa de juros efetiva de 13,5% se forem feitos 12 pagamentos por ano?

=NOMINAL(13,5%;12) = 12,73%. A taxa de juros nominal por ano é 12,73%.

## NOMINAL_ADD

Calcula a taxa de juros nominal anual com base na taxa efetiva e o número de pagamentos de juros por ano.

As funções cujo nome terminem com _ADD ou _EXCEL2003 retornam os mesmos resultados que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

#### Sintaxe

NOMINAL(TaxaEfetiva; NPerA)

TaxaEfetiva é a taxa de juros efetiva anual.

NPerA é o número de pagamento de juros por ano.

#### Exemplo

Qual é a taxa nominal de juros para uma taxa de juros efetiva de 5,3543% e pagamento trimestral?

=NOMINAL_ADD(5,3543%;4) retorna 0,0525 ou 5,25%.

## OTN

Calcula o retorno anual de uma letra do tesouro. Uma letra do tesouro é comprada na data de liquidação e vendida pelo valor de par total na data de vencimento, que deve ocorrer no mesmo ano. Um desconto é deduzido do preço de compra.

#### Sintaxe

OTN(Liquidação; Vencimento; Desconto)

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Desconto é o desconto percentual na aquisição do título.

#### Exemplo

Data de liquidação: 31 de março de 1999, data de vencimento: 1 de junho de 1999, desconto: 9,14 por cento.

O retorno sobre uma letra do tesouro correspondente a um título é tratado da seguinte maneira:

=OTN("1999-03-31";"1999-06-01"; 0.0914) retorna 0,094151 ou 9,4151 por cento.

## OTNLUCRO

Calcula o rendimento de uma letra do tesouro.

#### Sintaxe

OTNLUCRO(Liquidação; Vencimento; Preço)

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Preço é o preço (preço de aquisição) da letra do tesouro por 100 unidades monetárias do valor nominal.

#### Exemplo

Data de liquidação: 31 de março de 1999, data de vencimento: 1 de junho de 1999, preço: 98,45 unidades monetárias.

O lucro da letra do tesouro é tratado da seguinte maneira:

=OTNLUCRO("1999-03-31";"1999-06-01"; 98,45) retorna 0,091417 ou 9,1417 por cento.

## OTNVALOR

Calcula o preço de uma letra do tesouro por 100 unidades monetárias.

#### Sintaxe

OTNVALOR(Liquidação; Vencimento; Desconto)

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Desconto é o desconto percentual na aquisição do título.

#### Exemplo

Data de liquidação: 31 de março de 1999, data de vencimento: 1 de junho de 1999, desconto: 9 por cento.

O preço de uma letra do tesouro é tratado da seguinte maneira:

=OTNVALOR("1999-03-31";"1999-06-01"; 0,09) retorna 98,45.

## PDURAÇÃO

Calcula o número de períodos necessários a um investimento para atingir o valor desejado.

#### Sintaxe

DURACAOP(Taxa; VP; VF)

Taxa é uma constante. A taxa de juros deve ser calculada para duração completa (período de duração). A taxa de juros periódica é calculada dividindo a taxa de juros pela duração calculada. A taxa interna para uma anuidade deve ser inserida como Taxa/12.

VP é o valor presente (atual). O valor à vista é o depósito à vista ou valor à vista atual de um reembolso em espécie. Um depósito deve ser sempre positivo e não pode ser 0 ou negativo.

VF é o valor esperado. O valor futuro determina o valor desejado (futuro) do depósito.

#### Exemplo

Com uma taxa de juros de 4,75%, um valor à vista de 25.000 unidades monetárias e um valor futuro de 1.000.000 unidades monetárias, uma duração de 79,49 períodos de pagamento é retornada. O pagamento periódico é o quociente resultante do valor futuro e da duração, nesse caso 1.000.000/79,49=12.850,20.

## PGTO

Retorna o pagamento periódico para uma anuidade com taxas de juros constantes.

#### Sintaxe

PGTO(Taxa; NPer; VP [; VF [; Tipo]])

Taxa é a taxa de juros periódica.

NPer é o número de períodos, durante o qual a anuidade é paga.

VP é o valor à vista presente na sequência de pagamentos.

VF (opcional) é o valor desejado (valor futuro) a ser alcançado no final dos períodos de pagamento.

Tipo (opcional) é a data de vencimento para os pagamentos periódicos. Tipo = 1 para pagamentos no início e Tipo = 0 para pagamentos no fim de cada período.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

#### Exemplo

Quais serão os pagamentos periódicos para uma taxa de juros anual de 1,99% se o período de pagamento for 3 anos e o valor à vista 25.000 unidades monetárias. Existem 36 meses como 36 períodos de pagamento e a taxa de juros por período de pagamento é de 1,99%/12.

=PGTO(1,99%/12;36;25000) = -715,96 unidades monetárias. O pagamento periódico mensal é, portanto, 715,96 unidades monetárias.

## PGTOPRINC

Retorna os juros cumulativos pagos para um período de investimento com taxa de juros constante.

#### Sintaxe

PGTOPRINC(Taxa; NPer; Pmt; VP; S; E; Tipo)

Taxa é a taxa de juros periódica.

NPer é o período de pagamento com o número total de períodos. NPER também pode ser um número fracionário.

PV é o valor atual na sequência de pagamentos.

S é o primeiro período.

E é o último período.

Tipo é a data de vencimento do pagamento no início ou no fim de cada período.

#### Exemplo

Quais serão as quantias liquidadas se a taxa de juros anual for de 5,5% para 36 meses? O valor à vista é de 15.000 unidades monetárias. A quantia liquidada é calculada entre o 10º e o 18º períodos. A data de pagamento será no final do período.

=PGTOPRINC(5,5%/12;36;15000;10;18;0) = -3669,74 unidades monetárias. A quantia entre o 10o. e o 18o. períodos é 3669,74 unidades monetárias.

## PGTOPRINC_ADD

Calcula o resgate cumulativo de um empréstimo em um período.

As funções cujo nome terminem com _ADD ou _EXCEL2003 retornam os mesmos resultados que as funções correspondentes do Microsoft Excel 2003 que não possuem o sufixo. Utilize as funções sem o sufixo para obter os resultados baseados em padrões internacionais.

#### Sintaxe

PGTOPRINC_ADD(Taxa; NPer; VP; InícioPeríodo; FimPeríodo; Tipo)

Taxa define a taxa de juros de cada período.

NPer é o número total de períodos de pagamento. A taxa e NPER devem se referir à mesma unidade, e, portanto, ambas serão calculadas anualmente ou mensalmente.

VP é o valor presente.

InícioPeríodo é o primeiro pagamento para o cálculo.

FimPeríodo é o último período de pagamento para o cálculo.

Tipo é a data de vencimento do pagamento no fim de cada período (Tipo = 0) ou no início do período (Tipo = 1).

#### Exemplo

Foi feito o seguinte empréstimo hipotecário para uma casa:

Taxa: 9,00 por cento ao ano (9% / 12 = 0,0075), Duração: 30 anos (períodos de pagamento = 30 * 12 = 360), VPL: 125.000 unidades monetárias.

Quanto você reembolsará no segundo ano da hipoteca (nos períodos de 13 a 24)?

=PGTOPRINC_ADD(0,0075;360;125000;13;24;0) retorna -934,1071

No primeiro mês, você estará reembolsando a quantia a seguir:

=PGTOPRINC_ADD(0,0075;360;125000;1;1;0) retorna -68,27827

## PPGTO

Retorna para um determinado período o pagamento sobre o principal para um investimento com base em pagamentos constantes e periódicos, e uma taxa de juros constante.

#### Sintaxe

PPGTO(Taxa; Período; NPer; VP [; VF [; Tipo]])

Taxa é a taxa de juros periódica.

Período é o período de amortização. P = 1 para o primeiro e P = NPer para o último período.

NPer é o número total de períodos, durante o qual a anuidade é paga.

VP é o valor à vista presente na sequência de pagamentos.

VF (opcional) é o valor (futuro) desejado.

Tipo (opcional) define a data de vencimento. F = 1 para pagamentos no início de um período e F = 0 para pagamentos no fim de um período.

Nas funções do LibreOffice Calc, os parâmetros marcados como «opcionais» podem ser ignorados apenas quando não se seguir um parâmetro. Por exemplo, em uma função com quatro parâmetros, em que os últimos dois estão marcados como «opcionais», você pode ignorar o parâmetro 4 ou os parâmetros 3 e 4, mas não pode ignorar apenas o parâmetro 3.

#### Exemplo

De quanto é o pagamento mensal periódico a uma taxa de juros anual de 8,75% em um período de 3 anos? O valor à vista é 5.000 unidades monetárias e é pago sempre no início do período. O valor futuro é 8.000 unidades monetárias.

=PPGTO(8,75%/12;1;36;5000;8000;1) = -350,99 unidades monetárias.

## PREÇO

Calcula o valor de mercado de um título de juros fixos com um valor nominal de 100 unidades monetárias como uma função do lucro previsto.

#### Sintaxe

PREÇO(Liquidação; Vencimento; Taxa; Lucro; Resgate; Frequência [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Taxa é a taxa de juros nominal anual (taxa de juros do cupom)

Lucro é o lucro anual do título.

Resgate é o valor de resgate do título por 100 unidades monetárias do valor nominal.

Frequência é o número de pagamentos de juros por ano. (1, 2 ou 4).

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é comprado em 15-02-1999; a data de vencimento é 15-11-2007. A taxa de juros nominal é de 5,75%. O lucro é de 6,5%. O valor residual é de 100 unidades monetárias. Os juros são pagos duas vezes ao ano (a frequência é 2). Com o cálculo em base 0 o preço será o seguinte:

=PREÇO("1999-02-15"; "2007-11-15"; 0,0575; 0,065; 100; 2; 0) retorna 95,04287.

## PREÇODESC

Calcula o preço por 100 unidades monetárias do valor nominal de um título sem juros associados.

#### Sintaxe

PREÇODESC(Liquidação; Vencimento; Desconto; Resgate [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Desconto é o desconto de um título em porcentagem.

Resgate é o valor de resgate do título por 100 unidades monetárias do valor nominal.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Um título é comprado em 15-02-1999; a data de vencimento é 01-03-1999. O desconto em porcentagem é de 5,25%. O valor de resgate é 100. Ao calcular em base 2, o preço de desconto é o seguinte:

=PREÇODESC("1999-02-15"; "1999-03-01"; 0,0525; 100; 2) retorna 99,79583.

## PREÇOVENC

Calcula o preço por 100 unidades monetárias do valor nominal de um título, que paga juros na data do vencimento.

#### Sintaxe

PREÇOVENC(Liquidação; Vencimento; Emissão; Taxa; Lucro [; Base])

Liquidação é a data de compra do título.

Vencimento é a data de vencimento do título (expiração).

Emissão é a data de emissão do título.

Taxa é a taxa de juros do título na data de emissão.

Lucro é o lucro anual do título.

Base (opcional) é escolhida de uma lista de opções e indica como o ano será calculado.

Base | Cálculo
--- | ---
0 ou ausente | No método norte-americano (NASD), 12 meses de 30 dias cada
1 | Número exato de dias em cada mês, número exato de dias em um ano
2 | Número exato de dias em cada mês, ano com 360 dias
3 | Número exato de dias no mês, ano com 365 dias
4 | Método europeu, 12 meses de 30 dias cada

#### Exemplo

Data de liquidação: 15 de fevereiro de 1999, data de vencimento: 13 de abril de 1999, data de emissão: 11 de novembro de 1998. Taxa de juros: 6,1 por cento, lucro: 6,1 por cento, base: 30/360 = 0.

O preço é calculado como se segue:

=PREÇOVENC("1999-02-15";"1999-04-13";"1998-11-11"; 0,061; 0,061;0) retorna 99,98449888.

## VPL

Retorna o valor atual de um investimento com base em uma série de fluxos de caixa periódicos e em uma taxa de desconto. Para obter o valor presente líquido, subtraia o custo do projeto (o fluxo de caixa inicial no momento zero) do valor de retorno.

Se os pagamentos ocorrerem em intervalos irregulares, utilize a função XVPL.

#### Sintaxe

VPL(Taxa; Número 1 [; Número 2 [; … [; Número 254]]])

Taxa é a taxa de desconto para um período.

Número 1; Número 2; … ; Número 254 são números, referências a células ou intervalos contendo números.

Esta função ignora qualquer texto ou célula vazia num intervalo de dados. Se suspeitar de resultados errados desta função, procure por texto nos intervalos de dados. Para destacar o conteúdo do texto em um intervalo de dados, use o recurso destaque de valor .

#### Exemplo

Qual é o valor líquido atual de pagamentos periódicos de 10, 20 e 30 unidades monetárias com uma taxa de desconto de 8,75%. No momento zero os custos foram pagos segundo -40 unidades monetárias.

=VPL(8,75%;10;20;30) = 49,43 unidades monetárias. O valor presente líquido é o valor retornado menos o custo inicial de 40 unidades monetárias, portanto 9,43 unidades monetárias.

Voltar às funções financeiras - Parte 1

Avançar para Funções Financeiras: Parte 3

Funções por categoria