Contenido

# Función PROMEDIO.SI

Devuelve la media aritmética de todas las celdas en un intervalo que satisfaga una condición dada. La función PROMEDIO.SI suma todos los resultados que coincidan con la prueba lógica y divide esta suma por la cantidad de valores seleccionados.

Esta función está disponible desde la versión 4.0 de LibreOffice.

### Sintaxis

PROMEDIO.SI(Intervalo; Criterio [; Intervalo_promedio])

Intervalo (argumento obligatorio): una matriz, un nombre de intervalo o una etiqueta de columna o fila que contiene los números por promediar o el texto de la condición.

Criterio: Un criterio es una única celda Referencia, Número o Texto. Se utiliza en las comparaciones con el contenido de las celdas.

Una referencia a una celda vacía se interpreta como el valor numérico 0.

Una expresión coincidente puede ser:

- Un número o valor lógico. Un contenido de celda que coincida con el número o valor lógico.

- Un valor que comienza con un comparador (<, <=, =, >, >=, <>).

  En el caso de =, si el valor está vacío, coincide con las celdas vacías.

  En el caso de <>, si el valor está vacío coincide con las celdas no vacías.

  Para <>, si el valor no está vacío coincide con cualquier contenido de la celda excepto el valor, incluyendo las celdas vacías.

  Nota"=0" no coincide con las celdas vacías.

  Para = y <>, si el valor no está vacío y no puede interpretarse como un tipo Número o uno de sus subtipos y la propiedad Los criterios de búsqueda = y <> deben aplicarse a las celdas completas está marcada, la comparación se realiza contra todo el contenido de la celda, si no está marcada, la comparación se realiza contra cualquier subparte del campo que coincida con los criterios. Para = y <>, si el valor no está vacío y no puede interpretarse como un tipo de Número o se aplica uno de sus subtipos.

- Otro valor de texto. Si la propiedad Criterios de búsqueda = y <>debe aplicarse a celdas completas es verdadera, la comparación es con todo el contenido de la celda, si es falso, la comparación es contra cualquier subparte del campo que coincida con los criterios. La expresión puede contener texto, números, expresiones regulares o comodines (si está activado en las opciones de cálculo).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

Intervalo_promedio (opcional): el intervalo de valores para calcular la media.

Si no se especifica el Intervalo_promedio, Intervalo se utiliza tanto para el cálculo de la media como para la búsqueda, en función de la condición. Si se proporciona el Intervalo_promedio, el Intervalo se emplea solo para la prueba de la condición, mientras que Intervalo_promedio se emplea en el cálculo del promedio.

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

Si en el intervalo de valores para calcular la media hay una celda vacía o que contiene texto, la función PROMEDIO.SI la ignorará.
Si todo el intervalo está vacío, contiene solo texto o ninguno de los valores satisfacen la condición (o cualquier combinación de estas circunstancias), la función devolverá el error #¡DIV/0!

#### Ejemplo

Tenga en cuenta la tabla siguiente

| A | B | C
1 | Nombre de producto | Ventas | Ingresos
2 | lápiz | 20 | 65
3 | pluma | 35 | 85
4 | cuaderno | 20 | 190
5 | libro | 17 | 180
6 | estuche | no | no

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.

#### Uso simple

=PROMEDIO.SI(B2:B6;"<35")

Calcula el promedio de los valores en el intervalo B2:B6 que sean menores que 35. Devuelve 19 porque la segunda fila no se toma en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;"<"&MAX(B2:B6))

Calcula el promedio de valores del mismo intervalo que son menores que el valor máximo del intervalo. Devuelve 19 porque el valor mayor (la segunda fila) no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;">"&K.ESIMO.MENOR(B2:B6;1))

Calcula el promedio de valores del mismo intervalo que son mayores que el primer valor menor del intervalo. Devuelve 25 porque el valor menor (la cuarta fila) no se tiene en cuenta para realizar el cálculo.

#### Utilizar Intervalo_promedio

=PROMEDIO.SI(B2:B6;"<35";C2:C6)

La función busca qué valores son menores que 35 en el intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 145 porque la segunda fila no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;">"&MIN(B2:B6);C2:C6)

La función busca qué valores del intervalo B2:B6 son mayores que el valor mínimo del intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 113,3 porque la cuarta fila (que contiene el valor mínimo en el intervalo B2:B6) no se tiene en cuenta para realizar el cálculo.

=PROMEDIO.SI(B2:B6;"<"&K.ESIMO.MAYOR(B2:B6;2);C2:C6)

La función busca qué valores del intervalo B2:B6 son menores que el segundo valor mayor en el intervalo B2:B6 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Devuelve 180 porque en el cálculo solamente se tiene en cuenta la cuarta fila.

#### Utilizar expresiones regulares

=PROMEDIO.SI(A2:A6;"pan";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen solo la palabra «pan» y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 35 porque solo se tiene en cuenta la segunda fila para realizar el cálculo. La búsqueda se lleva a cabo en el intervalo A2:A6 pero se devuelven los valores del intervalo B2:B6.

=PROMEDIO.SI(A2:A6;"pan.*";B2:B6)

La función busca qué celdas del intervalo A2:A6 comienzan por «pan» terminando con cualquier cantidad de otros caracteres y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 27,5 porque ahora «panadero» satisface la condición y ambas filas, la primera y la segunda, se tienen en cuenta para realizar el cálculo.

=PROMEDIO.SI(A2:A6;".*libro.*";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen el término «libro» antecedido y sucedido por cualquier cantidad de caracteres distintos, y calcula el promedio de los valores correspondientes del intervalo B2:B6. Devuelve 18,5 porque solo las filas tercera y cuarta se tienen en cuenta para realizar el cálculo.

#### Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, se puede especificar en una celda separada y utilizar una referencia a esa celda en la condición de la función PROMEDIO.SI.

=PROMEDIO.SI(A2:A6;".*"&E2&".*";B2:B6)

La función busca qué celdas del intervalo A2:A6 contienen una combinación de caracteres especificada en E2 antecedida y sucedida por cualquier cantidad de caracteres distintos, y calcula el promedio de los valores correspondientes del intervalo B2:B6. Si E2 = libro, la función devuelve 18,5.

=PROMEDIO.SI(B2:B6;"<"&E2;C2:C6)

La función busca qué celdas del intervalo B2:B6 son menores que el valor especificado en E2 y calcula el promedio de los valores correspondientes del intervalo C2:C6. Si E2 = 35, la función devuelve 145.

Temas relacionados

AVERAGEIF wiki page.

PROMEDIO, PROMEDIOA, DESVPROM

CONTAR.SI.CONJUNTO, MIN.SI.CONJUNTO, Función MAX.SI.CONJUNTO, PROMEDIO.SI.CONJUNTO, SUMAR.SI.CONJUNTO

Lista de expresiones regulares