SignalTransition QML Type | Qt State Machine | Qt 6.11.1
Description: The SignalTransition type provides a transition based on a Qt signal.

- Qt 6.11
- Qt State Machine
- QML Types
- SignalTransition
- Qt 6.11.1 Reference Documentation

# SignalTransition QML Type

The SignalTransition type provides a transition based on a Qt signal. More...

Import Statement: | `import QtQml.StateMachine 6.11`
Inherits: | QSignalTransition

- List of all members, including inherited members

## Properties

- guard : bool
- signal : signal

## Detailed Description

SignalTransition is part of Qt State Machine QML API.

## Example Usage

     import QtQuick
     import QtQml.StateMachine as DSM

     Rectangle {
         DSM.StateMachine {
             id: stateMachine
             initialState: state
             running: true
             DSM.State {
                 id: state
                 DSM.SignalTransition {
                     targetState: finalState
                     signal: button.clicked
                     guard: guardButton.checked
                 }
             }
             DSM.FinalState {
                 id: finalState
             }
             onFinished: Qt.quit()
         }
         Row {
             spacing: 2
             Button {
                 id: button
                 text: "Finish state"
             }

             Button {
                 id: guardButton
                 checkable: true
                 text: checked ? "Press to block the SignalTransition" : "Press to unblock the SignalTransition"
             }
         }
     }

See also StateMachine, FinalState, and TimeoutTransition.

## Property Documentation

### guard : bool

Guard conditions affect the behavior of a state machine by enabling transitions only when they evaluate to true and disabling them when they evaluate to false.

When the signal associated with this signal transition is emitted the guard condition is evaluated. In the guard condition the arguments of the signal can be used as demonstrated in the example below.

     import QtQuick
     import QtQml.StateMachine as DSM

     Rectangle {
         Button {
             anchors.fill: parent
             id: button
             DSM.StateMachine {
                 DSM.State {
                     DSM.SignalTransition {
                         targetState: finalState
                         signal: button.mysignal
                         // the guard condition uses the mystr string argument from mysignal
                         guard: mystr == "test"
                     }
                 }
                 DSM.FinalState {
                     id: finalState
                 }
             }
             // define the signal the SignalTransition is connected with
             signal mysignal(mystr: string)
             // on clicking the button emit the signal with a single string argument
             onClicked: button.mysignal("test")
         }
     }

See also signal.

### signal : signal

The signal which is associated with this signal transition.

     import QtQuick
     import QtQml.StateMachine as DSM

     Rectangle {
         Button {
             anchors.fill: parent
             id: button
             DSM.StateMachine {
                 DSM.State {
                     DSM.SignalTransition {
                         targetState: finalState
                         signal: button.clicked
                     }
                 }
                 DSM.FinalState {
                     id: finalState
                 }
             }
         }
     }