WheelHandler QML Type | Qt Quick | Qt 6.11.1
Description: Handler for the mouse wheel.

- Qt 6.11
- Qt Quick
- QML Types
- WheelHandler
- Qt 6.11.1 Reference Documentation

# WheelHandler QML Type

Handler for the mouse wheel. More...

Import Statement: | `import QtQuick`
Inherits: | SinglePointHandler

- List of all members, including inherited members

## Properties

- acceptedDevices : flags
- acceptedModifiers : flags
- active : bool
- activeTimeout : real
- blocking : bool `(since 6.3)`
- enabled : bool
- invertible : bool
- margin : real
- orientation : enumeration
- parent : Item
- point : handlerPoint
- property : string
- rotation : real
- rotationScale : real
- target : Item
- targetScaleMultiplier : real
- targetTransformAroundCursor : bool

## Signals

- wheel(WheelEvent event)

## Detailed Description

WheelHandler is a handler that is used to interactively manipulate some numeric property of an Item as the user rotates the mouse wheel. Like other Input Handlers, by default it manipulates its target. Declare property to control which target property will be manipulated:

     import QtQuick

     Rectangle {
         width: 170; height: 120
         color: "green"; antialiasing: true

         WheelHandler {
             property: "rotation"
             onWheel: (event)=> console.log("rotation", event.angleDelta.y,
                                            "scaled", rotation, "@", point.position,
                                            "=>", parent.rotation)
         }
     }

BoundaryRule is quite useful in combination with WheelHandler (as well as with other Input Handlers) to declare the allowed range of values that the target property can have. For example it is possible to implement scrolling using a combination of WheelHandler and DragHandler to manipulate the scrollable Item's y property when the user rotates the wheel or drags the item on a touchscreen, and BoundaryRule to limit the range of motion from the top to the bottom:

     import QtQuick
     import Qt.labs.animation

     Item {
         width: 320; height: 480
         Flow {
             id: content
             width: parent.width
             spacing: 2; padding: 2

             WheelHandler {
                 orientation: Qt.Vertical
                 property: "y"
                 rotationScale: 15
                 acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
                 onActiveChanged: if (!active) ybr.returnToBounds()
             }

             DragHandler {
                 xAxis.enabled: false
                 onActiveChanged: if (!active) ybr.returnToBounds()
             }

             BoundaryRule on y {
                 id: ybr
                 minimum: content.parent.height - content.height
                 maximum: 0
                 minimumOvershoot: 400; maximumOvershoot: 400
                 overshootFilter: BoundaryRule.Peak
             }

             Repeater {
                 model: 1000
                 Rectangle { color: "gray"; width: 10 + Math.random() * 100; height: 15 }
             }
         }
     }

Alternatively, if property is not set or target is null, WheelHandler will not automatically manipulate anything; but the rotation property can be used in a binding to manipulate another property, or you can implement `onWheel` and handle the wheel event directly.

WheelHandler handles only a rotating mouse wheel by default; this can be changed by setting acceptedDevices.

See also MouseArea, Flickable, and Qt Quick Examples - Pointer Handlers.

## Property Documentation

### acceptedDevices : flags

The types of pointing devices that can activate this handler.

By default, this property is set to PointerDevice.Mouse, so as to react only to events from an actual mouse wheel.

WheelHandler can be made to respond to both mouse wheel and touchpad scrolling by setting acceptedDevices to `PointerDevice.Mouse | PointerDevice.TouchPad`.

Note: Some non-mouse hardware (such as a touch-sensitive Wacom tablet, or a Linux laptop touchpad) generates real wheel events from gestures. WheelHandler will respond to those events as wheel events even if `acceptedDevices` remains set to its default value.

### acceptedModifiers : flags

If this property is set, it will require the given keyboard modifiers to be pressed in order to react to wheel events, and otherwise ignore them.

If this property is set to `Qt.KeyboardModifierMask` (the default value), the WheelHandler ignores the modifier keys.

For example, an Item could have two handlers, one of which is enabled only if the required keyboard modifier is pressed, while the other ignores events if any modifier is pressed:

     import QtQuick

     Rectangle {
         width: 170; height: 120
         color: "green"; antialiasing: true

         WheelHandler {
             property: "rotation"
             acceptedModifiers: Qt.ControlModifier
         }

         WheelHandler {
             property: "scale"
             acceptedModifiers: Qt.NoModifier
         }
     }

The available modifiers are as follows:

Constant | Description
--- | ---
`NoModifier` | No modifier key is allowed.
`ShiftModifier` | A Shift key on the keyboard must be pressed.
`ControlModifier` | A Ctrl key on the keyboard must be pressed.
`AltModifier` | An Alt key on the keyboard must be pressed.
`MetaModifier` | A Meta key on the keyboard must be pressed.
`KeypadModifier` | A keypad button must be pressed.
`GroupSwitchModifier` | X11 only (unless activated on Windows by a command line argument). A Mode_switch key on the keyboard must be pressed.
`KeyboardModifierMask` | The handler does not care which modifiers are pressed.

See also Qt::KeyboardModifier.

### active : bool `[read-only]`

This holds `true` whenever the WheelHandler has recently seen a QWheelEvent, is keeping its properties up-to-date, and actively manipulating its target (if any).

See also activeTimeout.

### activeTimeout : real

The amount of time in seconds after which the active property will revert to `false` if no more wheel events are received. The default is `0.1` (100 ms).

When WheelHandler handles events that contain scroll phase information, such as events from some touchpads, the active property will become `false` as soon as an event with phase Qt::ScrollEnd is received; in that case the timeout is not necessary. But a conventional mouse with a wheel does not provide a scroll phase: the mouse cannot detect when the user has decided to stop scrolling, so the active property transitions to `false` after this much time has elapsed.

See also QWheelEvent::phase().

### blocking : bool `[since 6.3]`

Whether this handler prevents other items or handlers behind it from handling the same wheel event. This property is `true` by default.

This property was introduced in Qt 6.3.

### enabled : bool

If a PointerHandler is disabled, it will reject all events and no signals will be emitted.

If a PointerHandler's parent is disabled, the handler will also be effectively disabled, even when the `enabled` property remains `true`.

Note: HoverHandler behaves differently: see the documentation of its enabled property for more information.

### invertible : bool

Whether or not to reverse the direction of property change if QWheelEvent::inverted is `true`. The default is `true`.

If the operating system has a "natural scrolling" setting that causes scrolling to be in the same direction as the finger movement, then if this property is set to `true`, and WheelHandler is directly setting a property on target, the direction of movement will correspond to the system setting. If this property is set to `false`, it will invert the rotation so that the direction of motion is always the same as the direction of finger movement.

### margin : real

The margin beyond the bounds of the parent item within which the WheelHandler can react. For example if `margin` is set to `10`, you could place the cursor up to 10 pixels outside the visible edge of the item, and it will still react to the wheel:

     import QtQuick

     Rectangle {
         width: 170; height: 120
         color: "green"; antialiasing: true

         WheelHandler {
             property: "rotation"
             margin: 10
         }
     }

The default value is `0`.

### orientation : enumeration

Which wheel to react to. The default is `Qt.Vertical`.

Not every mouse has a `Horizontal` wheel; sometimes it is emulated by tilting the wheel sideways. A touchpad can usually generate both vertical and horizontal wheel events.

### parent : Item

The Item which is the scope of the handler; the Item in which it was declared. The handler will handle events on behalf of this Item, which means a pointer event is relevant if at least one of its eventPoints occurs within the Item's interior. Initially target() is the same, but it can be reassigned.

See also target and QObject::parent().

### point : handlerPoint `[read-only]`

The eventPoint currently being handled. When no point is currently being handled, this object is reset to default values (all coordinates are 0).

### property : string

The property to be modified on the target when the mouse wheel is rotated.

The default is no property (empty string). When no target property is being automatically modified, you can use bindings to react to mouse wheel rotation in arbitrary ways.

You can use the mouse wheel to adjust any numeric property. For example if `property` is set to `x`, the target will move horizontally as the wheel is rotated. The following properties have special behavior:

Constant | Description
--- | ---
`scale` | scale will be modified in a non-linear fashion as described under targetScaleMultiplier. If targetTransformAroundCursor is `true`, the x and y properties will be simultaneously adjusted so that the user will effectively zoom into or out of the point under the mouse cursor.
`rotation` | rotation will be set to rotation. If targetTransformAroundCursor is `true`, the l{QQuickItem::x}{x} and y properties will be simultaneously adjusted so that the user will effectively rotate the item around the point under the mouse cursor.

The adjustment of the given target property is always scaled by rotationScale.

### rotation : real

The angle through which the mouse wheel has been rotated since the last time this property was set, in wheel degrees.

A positive value indicates that the wheel was rotated up/right; a negative value indicates that the wheel was rotated down/left.

A basic mouse click-wheel works in steps of 15 degrees.

The default is `0` at startup. It can be programmatically set to any value at any time. The value will be adjusted from there as the user rotates the mouse wheel.

See also orientation.

### rotationScale : real

The scaling to be applied to the rotation property, and to the property on the target item, if any. The default is 1, such that rotation will be in units of degrees of rotation. It can be set to a negative number to invert the effect of the direction of mouse wheel rotation.

### target : Item

The Item which this handler will manipulate.

By default, it is the same as the parent, the Item within which the handler is declared. However, it can sometimes be useful to set the target to a different Item, in order to handle events within one item but manipulate another; or to `null`, to disable the default behavior and do something else instead.

### targetScaleMultiplier : real

The amount by which the target scale is to be multiplied whenever the rotation changes by 15 degrees. This is relevant only when property is `"scale"`.

The `scale` will be multiplied by `targetScaleMultiplier` angleDelta * rotationScale / 15. The default is `2` 1/3, which means that if rotationScale is left at its default value, and the mouse wheel is rotated by one "click" (15 degrees), the target will be scaled by approximately 1.25; after three "clicks" its size will be doubled or halved, depending on the direction that the wheel is rotated. If you want to make it double or halve with every 2 clicks of the wheel, set this to `2` 1/2 (1.4142). If you want to make it scale the opposite way as the wheel is rotated, set `rotationScale` to a negative value.

### targetTransformAroundCursor : bool

Whether the target should automatically be repositioned in such a way that it is transformed around the mouse cursor position while the property is adjusted. The default is `true`.

If property is set to `"rotation"` and targetTransformAroundCursor is `true`, then as the wheel is rotated, the target item will rotate in place around the mouse cursor position. If `targetTransformAroundCursor` is `false`, it will rotate around its transformOrigin instead.

## Signal Documentation

### wheel(WheelEvent event)

This signal is emitted every time this handler receives an event of type QWheelEvent: that is, every time the wheel is moved or the scrolling gesture is updated.

Note: The corresponding handler is `onWheel`.